GRADO: Decimo y Undécimo ASIGNATURA: Informática

PERIODO: DOCENTE:
ESTUDIANTE:

1. LOGRO: Desarrolla destrezas y habilidades lógicas para afrontar las soluciones de problemas en
forma algorítmica, usando además herramientas de software que permitan plasmar dicha
solución
2. Conceptos básicos teóricos.
PseInt
Es un software que interpreta pseudocódigo. Se puede descargar desde
https://sourceforge.net/projects/pseint/. Para su instalación generalmente se debe desactivar el
antivirus y el Windows defender (configuración de protección contra virus y amenazas). El perfil
recomendado en pseInt es el flexible.

En Pseint existen los siguientes tipos de datos:

 Numérico: enteros y decimales, los decimales se separan con un punto
 Lógico o Booleano: V y F
 Carácter: caracteres y cadena de caracteres, pueden ir encerrados entre comillas simples o
dobles

Los tipos de datos son determinados automáticamente cuando se crean las variables o se les
asigna un valor.

Los operadores algebraicos, relacionales y lógicos, así como la operación modulo no presentan
alteración alguna para su implementación.

Los comentarios se inicializan con //.

Algunas funciones preestablecidas en PseInt son:

Acciones Secuenciales:
Asignación: permiten guardar un valor en una variable mediante el botón “Asignar”.
C=2;

Escribir: nos permite mostrar en pantalla algún texto o dato, o varios datos separados por coma.
Escribir "El valor guardado en C es "
Escribir c;

Leer: nos permite capturar valores por teclado y guardarlos en una variable.

Ej: diseñe el pseudocódigo en pseint un programa que pida y suma 2 números.

Escribir "El primer número "

Leer a;
Escribir "El segundo número "
Leer b;
Escribir "El resultado de la suma es ",a+b;
Estructuras de control condicional SI
Si la condición se cumple se deben ejecutar todas las acciones después del entonces y si la
condición no se cumple se ejecutan todas las acciones después del sino. Se implementa con el
botón “Si-entonces”.

Ejercicio: diseñe un seudocódigo en pseInt para evaluar si el usuario es mayor de edad.

Algoritmo Prueba
Escribir 'Digite su edad: ';
Leer a;
Si a>17 Entonces
Escribir "Usted es mayor de edad ";
Sino
Escribir "Usted NO es mayor de edad ";
Fin Si
FinAlgoritmo

Estructuras de control condicional Segun

La ejecución de las acciones depende del valor de una variable numérica. Esta estructura es
recomendable para manejar menús complejos. Se implementa con el botón “Segun”.

Ejercicio 1: Usando la instrucción escribir diseñe el menú de un restaurante con 3 platos

diferentes.

Algoritmo Prueba
Escribir 'Bienvenido al restaurante. ';
Escribir 'elija un plato: ';
Escribir '1. Frijoles ';
Escribir '2. Arroz ';
Escribir '3. Lentejas ';
FinAlgoritmo

Ejercicio 2: Usando la estructura según, validar el plato seleccionado por el usuario:

Algoritmo Prueba
Escribir 'Bienvenido al restaurante. ';
Escribir 'elija un plato: ';
Escribir '1. Frijoles ';
Escribir '2. Arroz ';
Escribir '3. Lentejas ';
Leer a;
Segun a Hacer
1:
Escribir 'Usted ha elegido Frijoles ';
2:
Escribir 'Usted ha elegido Arroz ';
3:
Escribir 'Usted ha elegido Lentejas ';
De Otro Modo:
Escribir 'Usted no ha elegido ninguna válida ';
Fin Segun
FinAlgoritmo
 Estructura de control Para
Se conocen el número de iteraciones de un grupo de instrucciones. En PseInt el valor de
incremento de la variable contadora se indica con el comando Paso.

Ejercicio2: Escriba en pseint el seudocódigo que imprima en pantalla los números del 1 al 35

Algoritmo Prueba
Para a<-1 Hasta 35 Con Paso 1 Hacer
Escribir 'El número es ',a;
Fin Para
FinAlgoritmo

Estructura de control Mientras

Ejecutar una secuencia de instrucciones repetidamente hasta que la condición no se cumpla.
Ejercicio: Diseñe un seudocódigo que pida y muestre el nombre del usuario mientras el digite la
letra ‘Y’
Algoritmo restaurante
Escribir "Escriba su nombre";
leer nombre;
respuesta='y';
Mientras respuesta=='y' Hacer
Escribir "Su nombre es ",nombre;
Escribir "Si desea ver el nombre de nuevo y/n ";
leer respuesta;
Fin Mientras
FinAlgoritmo

Este programa no presenta problema al usarlo con cadenas.

Estructura de control Repetir

Una secuencia de instrucciones se repita al menos una vez hasta que se cumpla una condición.
Ejercicio: escriba el pseudocódigo anterior utilizando la estructura repetir.
Algoritmo Prueba
Repetir
Escribir "Juan, Desea ver de nuevo su nombre? si/no";
Leer opc;
Hasta Que opc="no";
FinAlgoritmo

Ejercicio 144: Escriba el pseudocódigo que pida dos números e imprima luego el siguiente menú:
1. Suma
2. Resta
3. Multiplicación
4. División
5. Raíz cuadrada del primer número
6. Generar un número aleatorio

Debe mostrar el resultado de la operación seleccionada por el usuario.

 Algoritmo operaciones
Escribir "Ingrese el primer número: ";
leer a;
Escribir "Ingrese el segundo número: ";
leer b;
Escribir "Elija una operación:";
Escribir "1. Suma";
Escribir "2. Resta";
Escribir "3. Multiplicación";
Escribir "4. División";
Escribir "5. Raíz cuadrada del primero";
Escribir "6. Azar";
leer operacion;
Segun operacion Hacer
1:
Escribir "El resultado de la suma es ", a+b;
2:
Escribir "El resultado de la resta es ", a-b;
3:
Escribir "El resultado de la multiplicación es ", a*b;
4:
Escribir "El resultado de la división es ", a/b;
5:
Escribir "La raíz cuadrada del primer número es ", rc(a);
6:
Escribir "Generando un número al azar...", azar(31);
De Otro Modo:
Escribir "Opción No Válida";
Fin Segun
FinAlgoritmo

Arreglos
Son una estructura de datos que permite el almacenamiento de una serie de elementos del
mismo tipo. (empieza en 1 la posición en PseInt, pero se puede configurar la base desde
Configuraropciones del lenguaje)

La sentencia para definir un arreglo es la siguiente:

Dimension <identificador> [tamaño];
Ej: Dimension edades[3];

Para guardar un valor en una posición específica: edades[2]=3;

Para imprimir en pantalla una posición especifica: escribir edades[2];

Ejercicio1: crear un vector que almacene las edades de 6 estudiantes y las muestre luego en
pantalla.
 Algoritmo pruebas
Dimension nombres[6];
Dimension grados[6];
Para i<-1 Hasta 6 Con Paso 1 Hacer
Escribir "Digite el nombre ";
leer nombres[i];
Escribir "Digite el grado ";
leer grados[i];
Fin Para
Para i<-1 Hasta 6 Con Paso 1 Hacer
Escribir nombres[i]," esta en ", grados[i];
Fin Para
FinAlgoritmo

Ejercicio2: Modificar el programa anterior para que permita modificar la edad de cualquiera de los
estudiantes.

Algoritmo Prueba
Dimension Edades[3];
Para a<-1 Hasta 3 Con Paso 1 Hacer
Escribir 'escriba la edad del estudiante ';
Leer Edades[a];
Fin Para
Para a<-1 Hasta 3 Con Paso 1 Hacer
Escribir Edades[a];
Fin Para
Escribir 'Cual quiere modificar';
leer i;
Escribir 'Que edad tiene el nuevo estudiante';
leer Edades[i]
Para a<-1 Hasta 3 Con Paso 1 Hacer
Escribir Edades[a];
Fin Para
FinAlgoritmo

funciones Especiales
Esperar tecla
Esta función pausa la ejecución mientras espera a que el usuario presione una tecla
escribir "presione una tecla para continuar";
esperar tecla;

Borrar Pantalla
Esta función limpia la consola
Borrar Pantalla;
escribir "Pantalla borrada";
Esperar x segundos
Esta función pausa la ejecución durante los segundos o milisegundos indicados
 Esperar 3 segundos
Esperar 1000 milisegundos

Ejercicio: implementar un programa que simule la espera de una respuesta con cinco puntos
suspensivos. (Analizar el uso de Sin Saltar)
Algoritmo suspensivos
escribir "Procesando su solicitud";
Para a<-0 Hasta 4 Con Paso 1 Hacer
esperar 1 Segundos;
escribir "." Sin Saltar;
Fin Para
Escribir "Bienvenido Sr Usuario";
FinAlgoritmo

3. Actividad evaluativa.

 Diseñe un pseudocódigo que pida una cantidad de pesos colombianos, despliegue la

siguiente lista, haga la conversión dependiendo de la opción seleccionada por el usuario e
imprima su resultado donde muestre la equivalencia completa y lo más explícita posible:
.
Ejemplo: Seleccione una opción: (después de pedir los pesos colombianos)
1. Dólar
2. Yen Japonés
3. BitCoin
4. Euros

Nota: Trabajar con las siguientes equivalencias, 1dolar = 3500 pesos colombianos, 1yen= 36
pesos colombianos, 1 bitcoin = 26958218 pesos colombianos, 1 euro = 4000 pesos colombianos.

4. Link de videos recomendados.

https://www.youtube.com/watch?v=SPIG14UV934&list=PLiplYDjUMtth8RvrndUPDVOMD20I4O2
Wd