Guía práctica de laboratorio de Computación

Segunda unidad: Algoritmos y Diagramas de Flujo

Práctica N°07: Estructura repetitiva

Apellidos :
Sección :
Nombres :
Fecha : / / Duración: 100 min
Docente :
Tipo de práctica: Individual ( x ) Grupal ( )

Instrucciones: Lea detenidamente cada enunciado y desarrolle lo solicitado.

Antes de iniciar la presente guía crear una carpeta en la unidad Alumno (G:) con sus apellidos, luego
guarde este archivo dentro de la misma también con sus apellidos. Utilizar el software PSeInt para el
diseño de los algoritmos.

Desarrolle en Pseudocódigo y Diagrama de Flujo de los siguientes ejercicios:

While (Mientras)

1.- Diseñe un algoritmo que muestre su nombre de forma indefinida, sin saltos de línea (ciclo infinito).

Proceso E01
Mientras 5>4 Hacer
Escribir Sin Saltar "Sixto ---> ";
FinMientras
FinProceso

2.- Diseñe un algoritmo que solicite el nombre de un usuario y muestre en pantalla 12 veces:
Acceso de [usuario] número [1]
Acceso de [usuario] número [2]
…
…
Acceso de [usuario] número [12]

Proceso E02
Definir user Como Caracter;
Definir c Como Entero;
Escribir "Ingrese nombre de usuario: ";
Leer user;
c<-1;
Mientras c<=12 Hacer
Escribir "Acceso de ",user," número ",c;
c<-c+1;
FinMientras
FinProceso
3.- Mostrar en pantalla la serie de 100 a 185, sin saltos de línea. Además, determinar la cantidad de
elementos que tiene la serie.

Proceso E03
Definir c,e como entero;
Escribir "Serie de 100 a 185: ";
c<-100;
e<-0;
Mientras c<=185 Hacer
Escribir Sin Saltar c,", ";
e<-e+1;
c<-c+1;
FinMientras
Escribir "";
Escribir "Cantidad de elementos: ",e;
FinProceso

4.- Realizar un algoritmo que solicite dos números y muestre el rango que hay entre ellos. (Ejemplo si se
ingresa 13 y 17, debe mostrar 13, 14, 15, 16, 17,). Finalmente mostrar la suma de los números de la serie.

Proceso E04
Definir A,B,c,sum como entero;
Escribir "Ingrese dos números (el segundo mayor): ";
Leer A,B;
c<-A;
sum<-0;
Mientras c<=B Hacer
Escribir Sin Saltar c,", ";
sum<-sum+c;
c<-c+1;
FinMientras
Escribir "";
Escribir "La suma de los elementos de la serie es ",sum;
FinProceso
5.- Escribir un programa que permita el ingreso de 15 números enteros y determine:
 La cantidad de pares.
 La cantidad de impares.
 El promedio de los números pares.
 La suma de todos los números.

Proceso E05
Definir c,N,par,imp,sum como entero;
Definir sump como Real;
c<-1;
par<-0;
imp<-0;
sump<-0;
sum<-0;
Mientras c<=15 Hacer
Escribir Sin Saltar "Ingrese número ",c,": ";
Leer N;
Si (N MOD 2=0) Entonces
par<-par+1; //contador de pares
sump<-sump+N; //acumulador de pares
SiNo
imp<-imp+1; //contador de impares
FinSi
sum<-sum+N;
c<-c+1;
FinMientras
Escribir "";
Escribir "Cantidad de pares ",par;
Escribir "Cantidad de impares ",imp;
Escribir "Promedio de pares ",sump/par;
Escribir "Sumatoria total ",sum;
FinProceso
5.1.- Modifica el programa anterior suponiendo que no se sabe la cantidad de números enteros a
ingresar.

...

6.- Algoritmo que calcule el factorial de un número entero, Ejemplo factorial de 5: 1 x 2 x 3 x 4 x 5 = 120.

Proceso E06
Definir c,N,F como Real;
Escribir "Ingrese un número: ";
Leer N;
c<-1;
F<-1;
Mientras c<=N Hacer
Escribir Sin Saltar c," x ";
F<-F*c;
c<-c+1;
FinMientras
Escribir "1 = ",F;
Escribir "El factorial de ",N," es ",F;
FinProceso

7.- Algoritmo que muestre la tabla de multiplicar del 1 al 12 de un número real ingresado por teclado.

Proceso E07
Definir N,c como entero;
Escribir "Ingrese un número: ";
Leer N;
Escribir "Tabla de multiplicar de ",N," del 1 al 12: ";
c<-1;
Mientras c<=12 Hacer
Escribir N," por ",c," es igual a ",N*c;
c<-c+1;
FinMientras
FinProceso
 Do While (Repetir)

8.- Algoritmo que solicite el ingreso de un número tantas veces, hasta que se ingrese el número cero,
finalmente mostrar la cantidad y la suma de números ingresados.

Proceso E08
Definir N,sum,can Como Entero;
sum<-0;
can<-0;
Repetir
Escribir Sin Saltar "Ingrese número (cero para finalizar): ";
Leer N;
sum<-sum+N;
can<-can+1;
Hasta Que N=0
Escribir "";
Escribir "Fin, ingreso cero";
Escribir "Cantidad de números ingresados: ",can-1;
Escribir "La suma de todos es ",sum;
FinProceso

9.- Crear un algoritmo que calcule la raíz cuadrada del número que introduzca el usuario. Si se introduce
un número negativo, debe mostrar un mensaje de error y volver a pedirlo tantas veces como sea
necesario, el programa finaliza cuando se ingresa un número neutro.

Proceso E09
Definir N Como Real;
Repetir
Escribir Sin Saltar "Ingrese número (cero para finalizar): ";
Leer N;
Si N<0 Entonces
Escribir "Error, no hay raíz de negativo..., ingrese de nuevo";
SiNo
Escribir "Su raíz cuadrada es ",rc(N);
FinSi
Hasta Que N=0
 Escribir "";
Escribir "Fin, ingreso cero";
FinProceso

Ejercicios planteados (Pseudocódigo):

1.- Imprimir un mensaje de bienvenida a un usuario, 5 veces. (Mientras)

Proceso E01
Definir user como caracter;
Definir c como entero;
Escribir "Ingrese nombre de usuario: ";
Leer user;
c<-1;
Mientras c<=5 Hacer
Escribir "Bienvenido ",user;
c<-c+1;
FinMientras
FinProceso

2.- Calcular la suma de los 75 primeros números enteros múltiplos de 7. (Mientras)

Proceso E02
Definir c,suma como entero;
Escribir "Serie de 1 a 75 de múltiplos de 7";
c<-1;
suma<-0;
Mientras c<=75 Hacer
Si (c MOD 7=0) Entonces
Escribir Sin Saltar c," + ";
suma<-suma+c;
FinSi
c<-c+1;
FinMientras
Escribir "0 = ",suma;
Escribir "La suma de la serie es ",suma;
FinProceso
3.- Calcular el IGV (18%) de distintos montos hasta ingresar un monto negativo (Repetir)

Proceso E03
Definir M,sum Como Real;
sum<-0;
Repetir
Escribir "";
Escribir Sin Saltar "Ingrese monto (soles): ";
Leer M;
Si M<=0 Entonces
Escribir "Monto incorrecto";
SiNo
Escribir Sin Saltar "Su IGV es ",M*0.18," soles";
Escribir "";
FinSi
Hasta Que M<0
Escribir "";
Escribir "Fin, ingreso un valor negativo";
FinProceso

4.- Mostrar si un número es positivo o negativo hasta que se ingrese el número cero. (Repetir)

Proceso E04
Definir M,sum Como Real;
sum<-0;
Repetir
Escribir "";
Escribir Sin Saltar "Ingrese número entero: ";
Leer M;
Si M<0 Entonces
Escribir Sin Saltar "Es negativo";
FinSi
Si M=0 Entonces
Escribir Sin Saltar "Es neutro";
FinSi
Si M>0 Entonces
Escribir Sin Saltar "Es positivo";
FinSi
Hasta Que M=0
Escribir "";
Escribir "Fin, ingreso cero";
FinProceso

5.- Un ciclista se ejercita recorriendo cinco kilómetros, pero decide aumentar su rendimiento físico
incrementado cinco kilómetros cada día. Determine la cantidad de kilómetros que habrá recorrido al
cabo de una cantidad de días.

Proceso E05
Definir CD,c,sum Como Entero;
Escribir "Ingrese cantidad de días: ";
Leer CD;
c<-1;
sum<-0;
Mientras c<=CD Hacer
Escribir "Dia ",c," = ",c*5," Kms";
sum<-sum+(c*5);
c<-c+1;
FinMientras
Escribir "Total de recorrido: ",sum," kilometros";
FinProceso
6.- Diseñar un algoritmo que determine el mayor y menor de 16 números enteros ingresados (Mientras).

Proceso E06
Definir c,num,nmen,nmay como entero;
c<-1;
nmen<-9999;
nmay<--9999;
Mientras c<=16 Hacer
Escribir Sin Saltar "Ingrese número ",c," :";
Leer num;
Si num<nmen Entonces
nmen<-num;
FinSi
Si num>nmay Entonces
nmay<-num;
FinSi
c<-c+1;
FinMientras
Escribir "";
Escribir "El mayor es ",nmay;
Escribir "El menor es ",nmen;
FinProceso

Referencias bibliográficas consultadas y/o enlaces recomendados

 JOYANES, L. (2008). Fundamentos de Programación. Algoritmos, estructura de datos y objetos,
4ª Edición. Madrid: McGraw-Hill.
 Beekman, G., Pacheco, R. y Tábora, A. (2008). Introducción a la computación. México: Pearson
Educación.