INSTITUCIÓN EDUCATIVA DEPARTAMENTAL PÍO XII

Pacho, Cundinamarca
Soy calidad
Soy Pío XII

ACTIVIDADES DE EJEMPLO ROBOMIND

En estos programas de ejemplo usted verá cómo las instrucciones y estructuras básicas de programación
pueden llevar a un comportamiento interesante del robot.
Trate de entender la escritura y por qué funciona.
Lo mejor es probarlos copiando el código y pegándolo en el panel de script RoboMind.
Asegúrese de que el escenario de la derecha es el que se debe utilizar antes de ejecutarlos.

 Ejercicio 1: Escriba su nombre

 Ejercicio 2: Encontrar el punto blanco
 Ejercicio 3: Línea seguidor
 Ejercicio 4: Corredor de laberintos

Ejercicio 1: Escriba su nombre

Debido a que el robot es capaz de pintar y crear programas sencillos de

dibujo. Utilizando pintarBlanco() y detenerPintar() puede ordenarle al
robot pintar en el suelo o no.
Cuando usted permite que el robot se mueva, se dejará una línea en el
suelo. De esta manera usted puede escribir caracteres como la 'A'.

En el mapa (escenario) openArea.map tendrá suficiente espacio para

crear una buena pieza de arte. Trate de usar el mando a distancia
(Corre > control remoto) para que el robot pinte.

#character 'A'
pintarBlanco()

adelante(2)
derecha()
adelante(1)
derecha()
adelante(2)
atras(1)
derecha()
adelante(1)

detenerPintar()

Página 1 de 5
ASIGNATURA: Tecnología e informática 8 GUIA No. 3
 INSTITUCIÓN EDUCATIVA DEPARTAMENTAL PÍO XII
Pacho, Cundinamarca
Soy calidad
Soy Pío XII

Ejemplo 2: Encontrar el punto blanco

En el mapa (escenario) findSpot1.map, se encuentra una mancha blanca

en una esquina al lado izquierdo. Supongamos que no se sabe a qué
distancia se encuentra la mancha blanca. ¿Cómo encuentra la mancha
blanca el robot?
Deje que el robot de un paso adelante, y compruebe mirando a la
izquierda si hay una mancha. De lo contrario debe dar otro paso
adelante y volver a comprobar si ya está cerca del lugar. Esto puede
repetirse con un bucle (repetir).

repetir(){
si(izquierdaEsBlanco()){
# Hay una mancha blanca a su izquierda
izquierda()
adelante(1)
fin
}
otro{
# No hay ninguna mancha blanca todavía
adelante(1)
}
}

Otro código que muestra los mismos resultados es el siguiente script. Aquí el robot repite el movimiento
hacia adelante hasta que no ve más la pared. A continuación, el robot gira y se mueve hacia adelante.

repetirMientras(izquierdaEsObstaculo()){
adelante(1)
}

izquierda()
adelante(1)

Página 2 de 5
ASIGNATURA: Tecnología e informática 8 GUIA No. 3
 INSTITUCIÓN EDUCATIVA DEPARTAMENTAL PÍO XII
Pacho, Cundinamarca
Soy calidad
Soy Pío XII

Ejemplo 3: Seguidor de línea

En el mapas default.map se encuentra una línea blanca. Esta línea forma una
pista a través del medio ambiente. ¿Cómo puede hacer que el robot siga
esta pista?
La solución es algo similar al ejemplo anterior. Después de que el robot se
pone al principio de la pista, se determina lo que debe hacer paso a paso.

# Ir al inicio de la línea
derecha()
adelante(8)

# Sigue paso a paso la pista

repetir()
{
si(frenteEsBlanco()){
adelante(1)
}
otro si(derechaEsBlanco()){
derecha()
}
otro si(izquierdaEsBlanco()){
izquierda()
}
otro si(frenteEsObstaculo()){
fin
}
}

Otro método es usar procedimientos, este código funciona de igual manera.

# Ir al inicio de la línea
derecha()
adelante(8)

# iniciar el seguimiento
seguir()

Página 3 de 5
ASIGNATURA: Tecnología e informática 8 GUIA No. 3
 INSTITUCIÓN EDUCATIVA DEPARTAMENTAL PÍO XII
Pacho, Cundinamarca
Soy calidad
Soy Pío XII

# Definición recursiva para el seguimiento.

procedimiento seguir(){
si(frenteEsBlanco()){
adelante(1)
seguir()
}
otro si(derechaEsBlanco()){
derecha()
seguir()
}
otro si(izquierdaEsBlanco()){
izquierda()
seguir()
}
otro si(frenteEsObstaculo()){
# Finalizar la llamada al procedimiento en curso
# (porque no hay nada para después
# Regresar este, todas las llamadas se terminarán
# y el programa se detiene)
fin
}
}

Ejemplo 4: Corredor de laberintos

¿Cómo escapar de un laberinto? Parece que esta difícil pregunta tiene una
solución simple. Por siempre siguiendo la pared a la derecha (o siempre
siguiendo la pared en el lado izquierdo) se encuentra la salida con seguridad.

El siguiente script hace que el robot encuentra la Baliza en la maze1.map.

repetir(){
si(derechaEsObstaculo()){
si(frenteEsClaro()){
adelante(1)
}

Página 4 de 5
ASIGNATURA: Tecnología e informática 8 GUIA No. 3
 INSTITUCIÓN EDUCATIVA DEPARTAMENTAL PÍO XII
Pacho, Cundinamarca
Soy calidad
Soy Pío XII

otro{
izquierda()
}
}
otro{
derecha()
adelante(1)
}

si(frenteEsBaliza()){
tomar()
fin
}
}
Tomado de: https://www.robomind.net/es/docExamples.htm

Página 5 de 5
ASIGNATURA: Tecnología e informática 8 GUIA No. 3