PROGRAMACION DIGITAL

Estructuras de Control CICLICAS-REPETITIVAS-BUCLES

Sesion-05

Prof. Fernando Mendoza Apaza

Capacidad:
Aplica estructuras repetitivas While,
DO While, FOR en el desarrollo de
aplicaciones.
PROCESOS CONDICIONALES / MULTIPLES
ESTRUCTURAS CICLICAS-REPETITIVAS-BUCLES
Se requiere un algoritmo para obtener la suma de diez cantidades mediante la utilización de
un ciclo “Mientras”. Realice el diagrama de flujo, el pseudocódigo para representarlo.
Se requiere un algoritmo para obtener la suma de diez cantidades mediante la utilización de
un ciclo “Mientras”. Realice el diagrama de flujo, el pseudocódigo para representarlo.

1. Inicio
2. Hacer SU = 0
3. Hacer C = 1
4. Mientras C < = 10

Leer VA
Hacer SU = SU + VA

Hacer C = C + 1
Fin mientras
5. Escribir SU
6. Fin
Ejemplo: Elaborar un programa capaz de sumar muchos
números, todos los que el usuario quisiera, y en el que
hubiera que escribir "0" para indicar que queremos terminar,
podría ser así:
Ejemplo: Elaborar un programa capaz de sumar muchos
números, todos los que el usuario quisiera, y en el que
hubiera que escribir "0" para indicar que queremos terminar,
podría ser así:

Algoritmo Mientras01
definir suma,x Como Entero;
Escribir "Dime un numero";
Leer x;
suma <- 0;

Mientras x <> 0 Hacer

suma <- suma + x;
Escribir "Hasta ahora, la suma es ", suma;
Escribir "Dime otro numero";
Leer x;
FinMientras

Escribir "Terminado";

FinAlgoritmo
Ejemplo: Elaborar un programa capaz de sumar muchos
números, todos los que el usuario quisiera, y en el que
hubiera que escribir "0" para indicar que queremos terminar,
podría ser así:

Algoritmo Repetir01
definir suma,x Como Entero;
suma <- 0;
Escribir "Dime un numero";
Leer x;
Repetir

suma <- suma + x;

Escribir "Hasta ahora, la suma es ", suma;
Escribir "Dime otro numero";
Leer x;
Hasta Que x = 0

Escribir "Terminado";

FinAlgoritmo
Ejemplo: Elaborar un programa capaz de sumar
muchos números, todos los que el usuario quisiera,
y en el que hubiera que escribir "0" para indicar
que queremos terminar, podría ser así:

Algoritmo Para01
definir suma,x,i,n,j Como Entero;
suma <- 0;n <- 2;j <- 0;
Escribir "Dime un numero";
Leer x;
Para i<-1 Hasta n+j Con Paso 1 Hacer
suma <- suma + x;
Escribir "Hasta ahora, la suma es ", suma;
Escribir "Dime otro numero";
Leer x;
si x<>0 entonces
j<-j+1;n<-n+1;
FinSi
Fin Para

Escribir "Terminado";

FinAlgoritmo
Ejemplo: Elabore un programa que pida al usuario una clave
de acceso, y que no le permita seguir hasta que la introduzca
correctamente, se podría hacer así:
Ejemplo: Elabore un programa que pida al usuario una clave
de acceso, y que no le permita seguir hasta que la introduzca
correctamente, se podría hacer así:

Algoritmo Mientras02
definir clave Como Entero;

Escribir "Dime tu clave de acceso";

Leer clave;
Mientras clave<> 1234 hacer
Escribir "Clave incorrecta";
Escribir "Dime tu clave de acceso";
Leer clave;
FinMientras

Escribir "Bienvenido!";

FinAlgoritmo
 Ejemplo: Elabore un programa que pida al usuario una
clave de acceso, y que no le permita seguir hasta que la
introduzca correctamente, se podría hacer así:

Algoritmo Repetir02
Definir clave Como Entero;
Repetir
Escribir "Dime tu clave de acceso";
Leer clave;
Si clave <> 1234 Entonces
Escribir "Clave incorrecta";
FinSi
Hasta Que clave=1234

Escribir "Bienvenido!";

FinAlgoritmo
Ejemplo: Elabore un programa que pida al usuario una clave
de acceso, y que no le permita seguir hasta que la introduzca
correctamente, se podría hacer así:
Por ejemplo, elabore un programa que mostrara los números
del 1 al 10, podría ser:

Algoritmo Para02
definir x Como Entero;

Para x <- 1 Hasta 10 Hacer

Escribir x;
FinPara

FinAlgoritmo
Las estructuras repetitivas ("bucles") se pueden incluir una dentro de otra si
fuera necesario. El resultado se conoce como un "bucle anidado".

Por ejemplo, si se desea dibujar un rectángulo usando asteriscos, se puede

plantear como escribir de forma repetitiva varias filas que, a su vez están
formadas cada una por varias columnas, de forma también repetitiva, como
muestra este ejemplo:
Las estructuras repetitivas ("bucles") se pueden incluir una dentro de otra si
fuera necesario. El resultado se conoce como un "bucle anidado".

Por ejemplo, si se desea dibujar un rectángulo usando asteriscos, se puede

plantear como escribir de forma repetitiva varias filas que, a su vez están
formadas cada una por varias columnas, de forma también repetitiva, como
muestra este ejemplo:
// Rectángulo formado por asteriscos
Algoritmo Para03_Rectangulo
Definir ancho, alto, fila,columna Como Entero;
Escribir Sin Saltar "Introduce el ancho: ";
Leer ancho;
Escribir Sin Saltar "Introduce el alto: ";
Leer alto;

Para fila<-1 Hasta alto Hacer

Para columna <- 1 Hasta ancho Hacer

Escribir Sin Saltar "#" ;
FinPara

Escribir "" ; // Avance de línea tras cada fila

FinPara

FinAlgoritmo