2014

UNANLEON
DPTO. DE COMPUTACION

UNIDAD II: ESTRUCTURA SECUENCIAL

LOGICA DE PROGRAMACION | M.SC. ANA MARIA SALGADO G.

Estructura Secuencial

ESTRUCTURA SECUENCIAL
La estructura secuencial permite representar aquellas instrucciones que se ejecutan una tras otra,
en secuencia; o sea, instrucciones en que la salida de una es la entrada de la prxima instruccin.
Mediante esta estructura se pueden representar instrucciones de asignacin, entrada y salida de
datos e invocacin a subprogramas.
Esta, como todas las estructuras de la programacin estructurada, tiene una sola entrada y una
sola salida.
Representacin
Proceso NombreProceso
<instruccin 1>
<instruccin 2>
<instruccin 3>
.
.
.
<instruccin n>
FinProceso

Ejemplo
Proceso suma
Escribir 'Ingrese dos enteros: ';
Leer a,b;
c<- a+b;
Escribir 'La suma es: ',c;
FinProceso
INSTRUCCIN DE ASIGNACION

Por medio de esta instruccin se asigna a una variable el resultado de

evaluar una expresin. Al lado izquierdo de la instruccin est la variable, al derecho la expresin
y unindolas el signo <-, denominado operador de asignacin.
Al ejecutarse la instruccin se evala la expresin, la cual da como resultado un nico valor; ste
es llevado a la direccin de memoria asignada a la variable que recibe la informacin. Al hacerse la
asignacin es destruida cualquier otro valor que tenga la variable. El dato o valor que arroje la

M.Sc. Ana Mara Salgado G.

Estructura Secuencial
expresin debe ser del mismo tipo que la variable: si el resultado es numrico la variable debe ser
numrica, si es lgico o carcter la variable tambin lo debe ser.
FORMATO
<variable> <- <expresin>
Existen dos operadores de asignacin alternativos que pueden utilizarse indistintamente en
cualquier caso, pero la habilitacin del segundo (=) depende del perfil de lenguaje seleccionado.
<variable> := <expresin> ;
<variable> = <expresin> ;
Ejemplos
SALDO <- VFINAL VINICIAL
RESUL <- (X > Y) ^ (B > C)
SUMA <- 0
VARIABLE1 <- VARIABLE2
NOMBRE <- CARMEN

INSTRUCCIN DE ENTRADA DE DATOS

Los datos de entrada son los valores necesarios para que la
computadora haga los clculos pertinentes.
Una instruccin de entrada de datos es una orden, para que desde
un medio externo se introduzcan valores y dichos datos sean
llevados a las direcciones de memoria, asignadas a las variables utilizadas para almacenar los datos
de entrada en el proceso.
La instruccin Leer permite ingresar informacin desde el ambiente.
Leer <variable1> , <variable2> , ... , <variableN> ;
Esta instruccin toma N valores desde el ambiente (en este caso el teclado) y los asigna a las N
variables mencionadas. Pueden incluirse una o ms variables, por lo tanto el comando leer uno o
ms valores.
FORMATO
Leer <lista de variables separadas por coma>;
Ejemplo
Leer CODIGO, NOMBRE;
Los valores que se introducen deben estar en el mismo orden de las variables en la lista.

M.Sc. Ana Mara Salgado G.

Estructura Secuencial
INSTRUCCIN DE SALIDA DE DATOS
Mediante la instruccin de salida se extraen valores de la
memoria hacia un medio externo de salida permitido. Se permite
acompaar los resultados con comentarios explicativos de los
valores que se muestran en el medio de salida.
FORMATO
Escribir <lista de variables separadas por comas o comentarios>;
La instruccin Escribir permite mostrar valores al ambiente.
Escribir <exprl> , <expr2> , ... , <exprN> ;
Esta instruccin informa al ambiente (en este caso escribiendo en pantalla) los valores obtenidos
de evaluar N expresiones. Dado que puede incluir una o ms expresiones, mostrar uno o ms
valores. Si hay ms de una expresin, se escriben una a continuacin de la otra sin separacin, por
lo que el algoritmo debe explicitar los espacios necesarios para diferenciar dos resultados si as lo
requiere.
Ejemplos
Proceso prueba
Escribir 'Ingrese tres valores:';
Leer A,B,C;
Escribir A;
Escribir B;
Escribir C;
Escribir 'Los valores son: ',A,' ',B,' ',C;
Escribir 'UNIVERSIDAD DE ANTIOQUIA';
Escribir 'El valor de A es:',A,' El de B es:',B,' Y el de C es:',C
FinProceso

Al ejecutarse cada una de las instrucciones anteriores, y si las variables A, B y C contienen los
valores: A = 30; B = 40.36; C = -443, las salidas sern:

M.Sc. Ana Mara Salgado G.

Estructura Secuencial
Cuando en una instruccin de salida se tiene un grupo de caracteres entre comillas ste ser
impreso sin ninguna modificacin en el medio de salida, y lo que aparezca sin comillas se asume
que es una variable; por lo tanto, se extraer de la memoria el contenido de sta.
Ejercicio resuelto
1. Dada una cantidad en crdobas, obtener la equivalencia en dlares, asumiendo que la
unidad cambiaria es un dato desconocido.
Datos de entrada
Cantidad en crdobas
Tipo de cambio.
Datos de salida
Nos piden como resultado:
Equivalencia en dlares.
Proceso
El clculo necesarios para obtener los resultados partiendo de los datos de entrada, son:
dolares = crdobas entre el tipo de cambio.
Definicin de variables
dolares:
Valor que representa el equivalente en dlares.
cordobas:
Valor que representa la cantidad en crdobas.
tipocambio:
Valor que representa la cantidad con que podemos comprar un dlar.

Pseudocdigo:
Proceso cambioMoneda
Definir dolares, cordobas, tipocambio Como Real;
Escribir "Ingrese la cantidad en cordobas que desea cambiar:";
Leer cordobas;
Escribir "Introduzca el tipo de cambio: ";
Leer tipocambio;
dolares = cordobas/tipocambio;
Escribir "El equivalente en dolares de ",cordobas, " cordobas es: ",dolares;
FinProceso
Prueba de escritorio
cordobas
1000

tipocambio
25.9

M.Sc. Ana Mara Salgado G.

dolares
38.61

Estructura Secuencial
Salida

Diagrama de flujo

Ejercicio resuelto
2. A la mam de Juan le preguntan su edad, y contesta: tengo 3 hijos, pregntele a Juan su
edad. Alberto tiene 2/3 de la edad de Juan, Ana tiene 4/3 de la edad de Juan y mi edad
es la suma de las tres. Hacer un algoritmo que muestre la edad de los cuatro.
Datos de entrada
Edad de Juan
Datos de salida
Edad de Alberto.
Edad de Juan. (En este caso, es un dato de entrada y salida al mismo tiempo).
Edad de Ana.
Edad de la mam.
M.Sc. Ana Mara Salgado G.

Estructura Secuencial
Proceso

Edad de Alberto = 2/3 * edad de Juan

Edad de Ana = 4/3 * edad de Juan
Edad de la mam = Edad de Alberto + Edad de Juan + Edad de Ana.

Definicin de variables
EDJUAN:
EDALBER:
EDANA:
EDMAMA:

Edad de Juan.
Edad de Alberto.
Edad de Ana.
Edad de la mam

Pseudocdigo:
Proceso edades
Definir EDJUAN, EDMAMA, EDANA, EDALBER como entero;
Escribir 'Ingrese la edad de Juan:';
Leer EDJUAN;
EDALBER <- 2 * EDJUAN / 3;
EDANA <- 4 * EDJUAN / 3;
EDMAMA <- EDJUAN + EDALBER + EDANA;
Escribir 'Las edades son:';
Escribir 'ALBERTO:', EDALBER, ' JUAN:', EDJUAN,' ANA:',EDANA,' MAMA:', EDMAMA;
FinProceso
Prueba de escritorio
Si el valor de la edad de Juan es 9, las otras edades sern:
EDJUAN
9

EDALBER
6

EDANA
12

EDMAMA
27

Salida

M.Sc. Ana Mara Salgado G.

Estructura Secuencial
Diagrama de flujo

Ejercicio resuelto
Hacer un seguimiento(prueba de escritorio) del siguiente grupo de instrucciones.
Proceso operaciones
SUMA <- 0;
X <- 20;
SUMA<-SUMA+X;
Z <- 40;
X <- X + Z ^ 2;
SUMA <- SUMA + X / Z;
Escribir 'EL VALOR DE LA SUMA ES: ', SUMA;
FinProceso
Prueba de escritorio
SUMA
X
Z
0
20
40
20
1620
60.5
La raya horizontal indica que el valor subrayado desaparece y es reemplazado por un nuevo valor.
Salida

M.Sc. Ana Mara Salgado G.

Estructura Secuencial
Aspectos a tener en cuenta:
En un algoritmo a las variables se les da valor, ya sea por una asignacin o por una
instruccin de entrada.
El valor que se le asigna a una variable debe ser del mismo tipo de dato que la
variable.
En la prueba de escritorio se deben mostrar los cambios que sufren todas las variables
del algoritmo.
Si una variable aparece en ms de una instruccin de entrada o asignacin, su valor es
destruido cada vez que se ejecuta una nueva instruccin.

Ms ejercicios resueltos
3. Un departamento de climatologa ha realizado recientemente su conversin al sistema
mtrico. Disear un algoritmo para realizar las siguientes conversiones:

Leer la temperatura dada en la escala Celsius e imprimir en su equivalente Fahrenheit (la
frmula de conversin es F= 9/5 C+32).

Leer la cantidad de agua en pulgadas e imprimir su equivalente en milmetros (25.5 mm = 1
pulgada).
Datos de entrada
Temperatura en grados Celsius.
Cantidad de agua en pulgadas.
Datos de salida
Temperatura en grados Fahrenheit.
Cantidad de agua en milmetros.
Definicin de variables
C: Representa la temperatura en grados Celsius.
F: Valor que representa la temperatura en grados Fahrenheit.
aguapulgadas:
Representa la cantidad de agua en pulgadas.
mm:
Valor que almacena la cantidad de agua en milmetros.
Pseudocdigo:
Proceso climatologia
Definir C, F, aguapulgadas, mm Como Real;
Escribir "Ingrese la temperatura en grados celsius: ";
leer C;
Escribir "Introduzca la cantidad de agua en pulgadas: ";
Leer aguapulgadas;
F= 9/5 * C + 32;
mm = aguapulgadas * 25.5;
Escribir C, " grados celsius equivalen a ",F, " grados fahrenheit";
M.Sc. Ana Mara Salgado G.

Estructura Secuencial
Escribir "En ",aguapulgadas, " pulgadas hay ",mm, " mm de agua";
FinProceso
Prueba de escritorio
C
30
22

F
86
71.6

aguapulgadas
10
25

mm
255
637.5

Salida:

4. El dueo de la United Motors paga a su personal de ventas un salario fijo mensual ms

una comisin de $50.00 por cada motocicleta vendida, ms el 5% del valor de las ventas.
Cada mes el Contador de la empresa ingresa el nombre del vendedor, el nmero de
motos vendidas y el valor total de las motocicletas. Calcule y escriba el salario total de
un vendedor.
Datos de entrada
Nombre del vendedor.
Nmero de motos vendidas.
Salario fijo del vendedor.
Valor de las motos.
Datos de salida
Salario total del vendedor.
Definicin de variables
nombre: Representa el nombre del vendedor.
numeromotos:
Valor que almacena la cantidad de motos vendidas.
valormoto: Representa el valor de una moto.
comision1, comision2:
Valor que almacena las comisiones ganadas por el vendedor.
ventas: Representa el costo de las ventas.
salariofijo: Almacena el salario del vendedor sin comisiones.
salariototal: Almacena el salario del vendedor incluyendo ya las comisiones por venta.

M.Sc. Ana Mara Salgado G.

10

Estructura Secuencial
Pseudocdigo:
Proceso Motos
Definir nombre Como Caracter;
Definir numeromotos como entero;
Definir valormoto, comision1, comision2, ventas, salariofijo, salariototal Como Real;
Escribir "Cual es el nombre del vendedor?: ";
Leer nombre;
Escribir "Cuantas motos ha vendido?: ";
Leer numeromotos;
Escribir "Ingrese el salario fijo: ";
leer salariofijo;
Escribir "Introduzca el valor de las motos: ";
Leer valormoto;
comision1 <- numeromotos * 50;
ventas = numeromotos * valormoto;
comision2 = ventas * 5 /100;
salariototal = salariofijo + comision1 + comision2;
Escribir "El vendedor ", nombre, " tiene un salario total de ", salariototal;
FinProceso
Prueba de escritorio:
nombre

numeromotos

valormoto

comision1

comision2

Juan
Reyes

10

2000

500

1000

ventas

20000

salariofijo

salariototal

500

2000

Salida:

M.Sc. Ana Mara Salgado G.

11

Estructura Secuencial
Diagrama de flujo:

5. Dada la matrcula y 5 calificaciones de un alumno obtenidas a lo largo del semestre;

construya un algoritmo que imprima la matrcula del alumno y el promedio de sus
calificaciones. Realice una prueba de escritorio con los valores siguientes:
MAT = 16500, 16650, 17225, 17240, 18240.
CAL1 = 8, 9, 9, 8.5, 7.3
CAL2 = 8.5, 8, 10, 9, 6.8
CAL3= 9, 9, 10, 7.5, 9.5
CAL4 = 7, 7, 8, 6, 8
CAL5 = 6, 9, 9, 6.5, 8.5
Datos de entrada
La matrcula.
Las 5 calificaciones
Datos de salida
La matrcula(En este caso, es un dato de entrada y salida al mismo tiempo).
Promedio
Proceso
PROM = suma de las 5 calificaciones divididas entre 5.

M.Sc. Ana Mara Salgado G.

12

Estructura Secuencial
Definicin de variables
MAT:
Matrcula del estudiante.
CAL1:
Valor que representa la calificacin 1 del alumno
CAL2:
Valor que representa la calificacin 2 del alumno
CAL3:
Valor que representa la calificacin 3 del alumno
CAL4:
Valor que representa la calificacin 4 del alumno
CAL5:
Valor que representa la calificacin 5 del alumno
PROM:
Valor que representa el promedio
Pseudocdigo:
Proceso promedio
Definir MAT como entero;
definir CAL1, CAL2, CAL3, CAL4, CAL5, PROM como real;
Escribir 'MATRICULA DEL ALUMNO:';
Leer MAT;
Escribir 'INGRESE 5 CALIFICACIONES:';
Leer CAL1, CAL2, CAL3, CAL4, CAL5;
PROM <- (CAL1 + CAL2+ CAL3 + CAL4 + CAL5)/5;
Escribir 'EL ALUMNO CON MATRICULA ', MAT, ' TIENE COMO PROMEDIO',PROM;
FinProceso
Prueba de escritorio
No.
De MAT
ejecucin
1
16500
2
16650
3
17225
4
17240
5
18240

CAL1
8
9
9
8.5
7.3

CAL2
8.5
8
10
9
6.8

CAL3
9
9
10
7.5
9.5

CAL4
7
7
8
6
8

CAL5
6
9
9
6.5
8.5

PROM
7.7
8.6
9.2
7.5
8.02

Salida para la ltima ejecucin

M.Sc. Ana Mara Salgado G.

13

Estructura Secuencial
Diagrama de flujo

6. Escriba un algoritmo que resuelva el problema que tienen en una gasolinera. Los
surtidores de la misma registran lo que surten en galones, pero el precio de la gasolina
est fijado en litros. El algoritmo debe calcular e imprimir lo que hay que cobrarle al
cliente.
Consideraciones:
Cada galn tiene 3.785 litros.
El precio del litro es $1.025
Datos de entrada
Galones surtidos
Datos de salida
Cobro del cliente.
Proceso

litros = galones surtidos * 3.785

cobro = cantidad de litros * 1.025

Definicin de variables
galones:
litros:
cobro:

Galones surtidos
Litros equivalentes a los galones surtidos
Cobro al cliente.

M.Sc. Ana Mara Salgado G.

14

Estructura Secuencial
Pseudocdigo:
Proceso gasolinera
Definir galones, litros, cobro como real;
Escribir 'Galones surtidos:';
Leer galones;
litros <- galones * 3.785;
cobro <- litros * 1.025;
Escribir 'Cobro al cliente = ', cobro;
FinProceso
Prueba de escritorio
galones
10.38

litros
39.29

cobro
40.27

Salida

Diagrama de flujo

M.Sc. Ana Mara Salgado G.

15

Estructura Secuencial

Ejercicios propuestos
1. Construya un pseudocdigo tal, que dados los tres lados de un tringulo, puede
determinar su rea. Esta la calculamos aplicando la siguiente frmula:
Area = S * (S L1) * (S L2) * (S L3)
S = (L1+L2+L3) / 2
2. Hacer un algoritmo que, dados los dos lados diferentes de un rectngulo, encuentre el
permetro y el rea del mismo. Al ser un rectngulo, conociendo los valores de los dos
lados diferentes podemos obtener los resultados solicitados.
Permetro = suma de los cuatro lados del rectngulo
Area = lado que representa la base * lado que representa la altura
3. Se tiene la siguiente informacin de un empleado:
Cdigo del empleado
Nombres
Nmero de horas trabajadas al mes
Valor de la hora trabajada
Porcentaje de retencin
Haga un algoritmo que muestre:
Cdigo, nombres, salario bruto y salario neto.
4. Construya un algoritmo tal, que dado el radio de un crculo, calcule e imprima su rea y la
longitud de su circunferencia.
El rea de un crculo la calculamos como: Area = * radio2
Circunferencia = 2 * * radio
Realice una prueba de escritorio (simulacin) con los valores de radio = 7.25, 11.14, 37.90,
1.31, 83.20
5. Un alumno desea saber cul ser su calificacin final en la materia de Algoritmos. Dicha
calificacin se compone de los siguientes porcentajes:
55% del promedio de sus tres calificaciones parciales.
30% de la calificacin del examen final.
15% de la calificacin de un trabajo final.
6. Un maestro desea saber qu porcentaje de hombres y que porcentaje de mujeres hay en
un grupo de estudiantes.
7. Tres personas deciden invertir su dinero para fundar una empresa. Cada una de ellas
invierte una cantidad distinta. Obtener el porcentaje que cada quien invierte con respecto
a la cantidad total invertida.

M.Sc. Ana Mara Salgado G.

16

Estructura Secuencial
Bibliografa

Oviedo Regino Efran M. Lgica de Programacin. 2da edicin.

Hernndez Mara Lourdes. Diseo estructurado de algoritmos. Diagramas de flujos y
pseudocdigos. Universidad de Teuxtepe, Mxico.
Osvaldo Cair. Metodologa de la programacin: Algoritmos, diagramas de flujo y
programas. Editorial COMPUTEC.

M.Sc. Ana Mara Salgado G.

17