Calendario DAX =

ADDCOLUMNS (
--- PARAMETROS DE FECHA
CALENDAR (
MIN (Sales[OrderDate]); -- FECHA INICIO
MAX (Sales[OrderDate]) + 365 -- FECHA FIN + 1 AÑO DE MAS
);
--- COLUMNAS QUE SALEN A PARTIR DE LOS PARAMETROS DE FECHA

-- DIA--
"Día"; DAY ( [Date] );
"Día_Semana"; FORMAT ( [Date]; "DDDD" );
"Día_Semana_Corto"; FORMAT ( [Date]; "DDD" );
"Inicio_de_Semana"; [Date]-WEEKDAY([Date])+1;
"Cierre_Semana";([Date] + 7 - WEEKDAY ( [Date]; 2 ));

-- SEMANA
"Num_Día_Semana"; WEEKDAY ( [Date]; 2 ); -- LUNES 1 Y DOMINGOS 7
"Semana_del_Mes";WEEKNUM ([Date];2) - WEEKNUM(EOMONTH([Date];-1) +1;2) + 1;
"Semana_7_Dias";DIVIDE(CEILING(DAY([Date]);7);7);
"Semana_Año"; WEEKNUM ( [Date]; 2 );

-- MES --
"Num_Mes"; MONTH ( [Date] );
"Mes"; FORMAT ( [Date]; "MMMM" );
"Días_en_el_Mes";DATEDIFF(DATE( YEAR([Date]); MONTH([Date]); 1);
EOMONTH([Date];0);DAY)+1;
"Inicio_Mes";DATE( YEAR([Date]); MONTH([Date]); 1);
"Final_Mes";EOMONTH([Date];0);
"Mes_Corto"; FORMAT ( [Date]; "MMM" );
"Año_Mes_Corto"; FORMAT ( [Date]; "mmm YYYY" );
"Mes_en_el_Trimestre";MONTH([Date]) - 3 * (QUARTER([Date]) - 1);

-- AÑO --
"Año"; YEAR ( [Date] );
"Inicio_de_Año";DATE( YEAR([Date]);1;1);
"Final_de_Año";DATE( YEAR([Date]);12;31);

-- TRIMESTE --
"Trimestre"; "Trim." & CONVERT(QUARTER ( [Date] );STRING);
"Num_Trimestre"; QUARTER ( [Date] );

-- SEMESTRE --
"Semestre"; "Semestre " & CONVERT((ROUNDUP(MONTH( [Date] )/6;0));STRING);
"Num_Semestre"; ROUNDUP(MONTH( [Date] )/6;0);

-- CUATRIMESTRE
"Cuatrimestre_Num";IF(MONTH([Date]) <= 4;1;IF(MONTH([Date]) > 4 && MONTH([Date]) <=
8;2;3));
"Cuatrimestre";IF(MONTH([Date]) <= 4;"Cuatrimestre 1";IF(MONTH([Date]) > 4 &&
MONTH([Date]) <= 8;
"Cuatrimestre 2";"Cuatrimestre 3"));

-- ORDEN COLUMNAS
"Num_Fecha"; INT(FORMAT ( [Date]; "YYYYMMDD" ));
"Num_Mes_Año"; INT(FORMAT ( [Date]; "YYYYMM00" ));
"Num_Año_Trimestre";INT(FORMAT ( [Date]; "YYYYQ000" ))
)