Algoritmo Restaurante

//Declaración de Variables
Definir entrada, platoFuerte, bebidas, postre, subtotal, seguir Como Entero;
Definir IVA, impConsumo, propina, Total, descuento Como Real;
Definir cliente Como Caracter;

seguir = 1;
//Ciclo
Mientras seguir == 1 Hacer
entrada=0;
platoFuerte=0;
bebidas=0;
postre=0;
cliente="";

//Se solicita al usuario los datos de consumo por el cliente

Escribir "Digite el nombre del Cliente: ";
Leer cliente;
Escribir "Digite el valor consumido como Entrada: ";
Leer entrada;
Escribir "Digite el valor consumido como Plato Fuerte: ";
Leer platoFuerte;
Escribir "Digite el valor consumido en Bebidas: ";
Leer bebidas;
Escribir "Digite el valor consumido en Postre: ";
Leer postre;

subtotal = entrada+platoFuerte+bebidas+postre;
IVA = subtotal * 0.16;
impConsumo = subtotal * 0.08;
propina = subtotal * 0.10;

//Sentencia de Control
Si subtotal > 200000 Entonces
Escribir "Descuento 5%";
descuento = subtotal * 0.05;
SiNo
Escribir "Descuento 2%";
descuento = subtotal * 0.02;
FinSi

Total = subtotal + IVA + impConsumo + propina - descuento;

Escribir "El Cliente ",cliente," consumió un Subtotal: ",subtotal;

Escribir "IVA (16%): ",IVA;
Escribir "Impuesto al Consumo (8%): ",impConsumo;
Escribir "Propina (10%): ",propina;
Escribir "Descuento: ",descuento;
Escribir "***********************************";
Escribir "Total a pagar: ",Total;

Escribir "Desea realizar otra Facturación? 1. Si, 2. No";

Leer seguir;
FinMientras
FinAlgoritmo