Documentos de Académico
Documentos de Profesional
Documentos de Cultura
Lugares Geométricos I 2020 Bgta - Actualizado
Lugares Geométricos I 2020 Bgta - Actualizado
Para esta parte del curso vamos a trabajar en el plano cartesiano X – Y, y vamos a utilizar
algunas funciones para definir y determinar lugares geométricos. Además, se va definir
una región “frontera” o región 0 (región cero)
Dado un punto (x1, y1) en el plano cartesiano, dada una ecuación de una recta de la
forma Y = m*X + b, dada una ecuación de un círculo concéntrico de la forma X2 + Y2 = r2,
tenga presente las siguientes proposiciones lógicas verdaderas:
1) El punto está en la recta, si cumple que y1 = m1*y1 + b1
2) El punto está por encima de la recta, si cumple que y1 > m1*y1 + b1
3) El punto está por debajo de la recta, si cumple que y1 < m1*y1 + b1
4) El punto está dentro del círculo, si cumple que x12 + y12 < r2
5) El punto está en el círculo, si cumple que x12 + y12 = r2
6) El punto está fuera del círculo, si cumple que x12 + y12 > r2
Nota: tenga presente las condiciones de igualdad y desigualdad presentes en estas 6
proposiciones lógicas
Actividad: tenga presente la siguiente figura donde se designan 13
lugares geométricos (no olvide el lugar 0)
Región 0 (“Frontera”): cualquier punto que esté sobre cualquiera de los ejes X-Y del plano
cartesiano, o sobre la recta y =-x, o sobre el círculo concéntrico de radio r
Región 1: cualquier punto que esté en el primer cuadrante dentro del círculo
Región 2: cualquier punto que esté en el primer cuadrante fuera del círculo
Región 3: cualquier punto que esté en el segundo cuadrante dentro del círculo y por encima de la
recta y=-x
Región 4: cualquier punto que esté en el segundo cuadrante fuera del círculo y por encima de la
recta y=-x
Región 5: cualquier punto que esté en el segundo cuadrante dentro del círculo y por debajo de la
recta y=-x
Región 6: cualquier punto que esté en el segundo cuadrante fuera del círculo y por debajo de la
recta y=-x
Región 7: cualquier punto que esté en el tercer cuadrante dentro del círculo
Región 8: cualquier punto que esté en el tercer cuadrante fuera del círculo
Región 9: cualquier punto que esté en el cuarto cuadrante dentro del círculo y por debajo de la
recta y=-x
Región 10: cualquier punto que esté en el cuarto cuadrante fuera del círculo y por debajo de la
recta y=-x
Región 11: cualquier punto que esté en el cuarto cuadrante dentro del círculo y por encima de la
recta y=-x
Región 12: cualquier punto que esté en el cuarto cuadrante fuera del círculo y por encima de la
recta y=-x
Solución para círculo con la recta y=-x (13 regiones). Ejecutar el siguiente programa “PseInt”
paso a paso con varios casos
Funcion posiRecta=VerRecta(s,t)
Definir posiRecta Como Caracter;
Si t>-s Entonces
posiRecta="Encima de la recta";
FinSi
Si t<-s Entonces
posiRecta="Debajo de la recta";
FinSi
FinFuncion
Funcion cuadrante=VerCuadrante (x,y)
Definir cuadrante Como Caracter;
Si x>0 Entonces
Si y>0 Entonces
cuadrante="Primer cuadrante";
SiNo
cuadrante="Cuarto cuadrante";
Escribir VerRecta(x,y);
FinSi
SiNo
Si y>0 Entonces
cuadrante="Segundo cuadrante";
Escribir VerRecta(x,y);
SiNo
cuadrante="Tercer cuadrante";
FinSi
FinSi
FinFuncion
Algoritmo LugarGeometrico1
/// Leer r (radio) en el rango [+5 .. +10]
/// Leer x1 y y1 en el rango [-1.5*r .. +1.5*r]
/// Determine el lugar donde se encuentra el punto leido
definir r,x1,y1 como real;
r=0.0;x1=20;y1=20;
mientras r<5 | r>10 hacer
escribir"Dar r[5 .. 10]:";leer r;
finmientras
escribir"r:",r;
mientras abs(x1)>1.5*r hacer
escribir"Dar x1[-1.5*r .. +1.5*r]:";leer x1;
finmientras
escribir"x1:",x1;
mientras abs(y1)>1.5*r hacer
escribir"Dar y1[-1.5*r .. +1.5*r]:";leer y1;
finmientras
escribir"y1:",y1;
si x1=0|y1=0|y1=-x1|x1^2+y1^2=r^2 entonces
Escribir"Frontera";
SiNo
Si x1^2+y1^2<r^2 Entonces
Escribir"Dentro del círculo";
Escribir VerCuadrante(x1,y1);
SiNo
Escribir"Fuera del círculo";
Escribir VerCuadrante(x1,y1);
FinSi
finsi
Finalgoritmo
Solución para círculo con dos rectas; la recta 1 es y = x, y la recta2 es y = -x
(17 regiones, 4 por cada cuadrante + la frontera)
Funcion posiRecta=VerRecta1(s,t)
Definir posiRecta Como Caracter;
Si t>s Entonces
posiRecta="Encima de la recta 1";
FinSi
Si t<s Entonces
posiRecta="Debajo de la recta 1";
FinSi
FinFuncion
Funcion posiRecta=VerRecta2(u,v)
Definir posiRecta Como Caracter;
Si v>-u Entonces
posiRecta="Encima de la recta 2";
FinSi
Si v<-u Entonces
posiRecta="Debajo de la recta 2";
FinSi
FinFuncion
Funcion cuadrante=VerCuadrante (x,y)
Definir cuadrante Como Caracter;
Si x>0 Entonces
Si y>0 Entonces
cuadrante="Primer cuadrante";
Escribir VerRecta1(x,y);
SiNo
cuadrante="Cuarto cuadrante";
Escribir VerRecta2(x,y);
FinSi
SiNo
Si y>0 Entonces
cuadrante="Segundo cuadrante";
Escribir VerRecta2(x,y);
SiNo
cuadrante="Tercer cuadrante";
Escribir VerRecta1(x,y);
FinSi
FinSi
FinFuncion
Algoritmo LugarGeometrico_2_2019
/// Leer r (radio) en el rango [+5 .. +10]
/// Leer x1 y y1 en el rango [-1.5*r .. +1.5*r]
/// Determine el lugar donde se encuentra el punto leído
definir r,x1,y1 como real;
escribir"Dar r[5 .. 10]:";leer r;
mientras r<5 | r>10 hacer
escribir" ..error.. Dar r[5 .. 10]:";leer r;
finmientras
escribir"r:",r;
escribir"Dar x1[-1.8*r .. +1.8*r]:";leer x1;
mientras abs(x1)>1.8*r hacer
escribir" ..error.. Dar x1[-1.8*r .. +1.8*r]:";leer x1;
finmientras
escribir"x1:",x1;
escribir"Dar y1[-1.8*r .. +1.8*r]:";leer y1;
mientras abs(y1)>1.8*r hacer
escribir" ..error.. Dar y1[-1.8*r .. +1.8*r]:";leer y1;
finmientras
escribir"y1:",y1;
escribir""
si x1=0|y1=0|y1=-x1|x1^2+y1^2=r^2 entonces
Escribir"Frontera";
SiNo
Si x1^2+y1^2<r^2 Entonces
Escribir"Dentro del círculo";
Escribir VerCuadrante(x1,y1);
SiNo
Escribir"Fuera del círculo";
Escribir VerCuadrante(x1,y1);
FinSi
finsi
Finalgoritmo
Actividad
Figura A Figura B
Identifique matemática y claramente los segmentos de recta del cuadrilátero irregular inscrito
en el círculo de la Figura A. Tenga presente las ecuaciones de las 3 rectas que están descritas a
continuación y describa los 10 lugares geométricos de la Figura B (incluyendo la Región 0)
Observe que la frontera para todas las rectas (la 1, la 2 y la 3) son segmentos y no toda la recta
para cada una de las rectas
Entonces conocida una coordenada (x1, y1) deben hacerse las siguientes consideraciones:
1) Para la frontera de la recta 1 además de cumplir la ecuación de la recta en el segmento,
también debe cumplirse que el valor de “x” debe estar en el rango [-r/2 .. +r] o que el valor
de “y” debe estar en el rango [-0.866r .. 0] y se podría expresar así:
(y1=m1*x1+b1)& (x1>(-r/2))&(x1<r) unidos por el operador lógico & (conjunción)
2) Para la frontera de la recta 2 además de cumplir la ecuación de la recta en el segmento,
también debe cumplirse que el valor de “x” debe estar en el rango [-r/2 .. 0] o que el valor
de “y” debe estar en el rango [0 .. +0.866r] y se podría expresar así:
(y1=m2*x1)& (x1>(-r/2))&(x1<0) unidos por el operador lógico & (conjunción)
3) Para la frontera de la recta 3 además de cumplir la ecuación de la recta en el segmento,
también debe cumplirse que el valor de “y” debe estar en el rango [-0.866r .. +0.866r] y se
podría expresar así:
(x1=(-r/2))& (y1>-0.866*r)&(y1<0.866*r) unidos por el operador lógico & (conjunción)
Entonces toda la expresión de la frontera podría (¿?) ser:
x1=0|y1=0|x1^2+y1^2=r^2|(x1=(-r/2))& (y1>-0.866*r)&(y1<0.866*r)| (y1=m1*x1+b1)& (x1>(-
r/2))&(x1<r)| (y1=m2*x1)& (x1>(-r/2))&(x1<0)
Una expresión bastante compleja, pero que puede codificarse en un algoritmo tal como se puede
ver a continuación:
Funcion VerCuadrante(x,y,m1,b1,m2,r)
Si x>0 Entonces
Si y>0 Entonces
escribir "Primer cuadrante";
SiNo
escribir "Cuarto cuadrante";
ver_r1(x,y,m1,b1)
FinSi
SiNo
Si y>0 Entonces
escribir "Segundo cuadrante";
si x<(-r/2) Entonces
Escribir "A la izquierda de la recta 3"
SiNo
ver_r2(x,y,m2)
FinSi
SiNo
escribir "Tercer cuadrante";
si x<(-r/2) Entonces
Escribir "A la izquierda de la recta 3"
SiNo
ver_r1(x,y,m1,b1)
FinSi
FinSi
FinSi
FinFuncion
Funcion ver_r1(x,y,m,b)
si y>x*m+b entonces
Escribir "Encima de la recta 1"
Escribir "A la derecha de la recta 3"
SiNo
Escribir "Debajo de la recta 1"
FinSi
FinFuncion
funcion ver_r2(x,y,m)
si y>m*x entonces
Escribir "Encima de la recta 2"
SiNo
Escribir "Debajo de la recta 2"
Escribir "A la derecha de la recta 3"
FinSi
FinFuncion
Algoritmo lugares_geometricos_04
definir r,x1,y1,m1,m2,b1,x2,y2 como real
r=0.0;x1=20;y1=20;
mientras r<5 | r>10 hacer
escribir"Dar r:";leer r;
finmientras
escribir"r:",r;
mientras abs(x1)>1.5*r hacer
escribir"Dar x1:";leer x1;
finmientras
escribir"x1:",x1;
mientras abs(y1)>1.5*r hacer
escribir"Dar y1:";leer y1;
finmientras
escribir"y1:",y1;Escribir""
// con la recta 2 y con la ayuda grafica suministrada
m2=-(rc(3)/2)/(1/2); // rc(3) = 1.7320508075688772
m1=-1/m2 // Aplicando principio de "perpendicularidad"
// intercepto de la recta 1
b1=0-m1*r // ( al reemplazar en la ecuación de la recta "y=mx+b")
Escribir"m1:",m1," ,b1:",b1," ,m2:",m2;Escribir""
//x1=0|y1=0|x1^2+y1^2=r^2|(x1=(-r/2))& (y1>-0.866*r)&(y1<0.866*r)|
(y1=m1*x1+b1)& (x1>(-r/2))&(x1<r)| (y1=m2*x1)& (x1>(-r/2))&(x1<0)
si x1=0|y1=0|x1^2+y1^2=r^2|(x1=(-r/2))&(y1>-0.866*r)&(y1<0.866*r)|
(y1=m1*x1+b1)&(x1>(-r/2))&(x1<r)|(y1=m2*x1)&(x1>(-r/2))&(x1<0) entonces
Escribir" ... Frontera ";
SiNo
Si x1^2+y1^2<r^2 Entonces
Escribir"Dentro del circulo";
VerCuadrante(x1,y1,m1,b1,m2,r);
SiNo
Escribir " ... Fuera del circulo"
FinSi
FinSi
FinAlgoritmo
Metodología “divide y reinaras”
- Se parte de lo general
- Se toman el todo y se analizan los elementos básicos por separado
- Se describen los elementos básicos que componen el todo
- Se usa variables lógicas para la descripción de los lugares geométricos detallados
Actividad
/// 14 regiones; círculo concéntrico; recta y=-x; "marco" externo
/// Leer r (radio) en el rango [+5 .. +10]
/// Leer x1 y y1 en el rango [-1.8*r .. +1.8*r]
/// Marco externo de coordenadas (+1.5*r,+1.5*r), (-1.5*r,-1.5*r)
/// Determine el lugar donde se encuentra el punto leído
Algoritmo LugarGeometrico_1_2020Ampliado
/// 14 regiones; círculo concéntrico; recta y=-x; "marco" externo
/// Leer r (radio) en el rango [+5 .. +10]
/// Leer x1 y y1 en el rango [-1.8*r .. +1.8*r]
/// Marco externo de coordenadas (+1.5*r,+1.5*r), (-1.5*r,-1.5*r)
/// Determine el lugar donde se encuentra el punto leído
///
definir r,x1,y1 como real;
definir k como entero
definir cu1,cu2,cu3,cu4,dentroC,fueraC,arribaR,abajoR,fueramarco,dentromarco como logico
definir r0,r1,r2,r3,r4,r5,r6,r7,r8,r9,r10,r11,r12,r13 como logico
escribir"Dar r[5 .. 10]:";leer r;
mientras r<5 | r>10 hacer
escribir" ..error.. Dar r[5 .. 10]:";leer r;
finmientras
escribir"r:",r;
escribir"Dar x1[-1.8*r .. +1.8*r]:";leer x1;
mientras abs(x1)>1.8*r hacer
escribir" ..error.. Dar x1[-1.8*r .. +1.8*r]:";leer x1;
finmientras
escribir"x1:",x1;
escribir"Dar y1[-1.8*r .. +1.8*r]:";leer y1;
mientras abs(y1)>1.8*r hacer
escribir" ..error.. Dar y1[-1.8*r .. +1.8*r]:";leer y1;
finmientras
escribir"y1:",y1;
/// evaluando las variables logicas para c/u de los cuadrantes
cu1=x1>0&y1>0;cu2=x1<0&y1>0;cu3=x1<0&y1<0;cu4=x1>0&y1<0;
/// evaluando las variables logicas para dentro y fuera del circulo
dentroC=x1^2+y1^2<r^2;fueraC=x1^2+y1^2>r^2;
/// evaluando las variables logicas para arriba y abajo de la recta y=-x
arribaR=y1>-x1;abajoR=y1<-x1;
/// evaluando las variables logicas para dentro y fuera del marco
fueramarco=(abs(x1)>1.5*r)|(abs(y1)>1.5*r);
dentromarco=(abs(x1)<1.5*r)&(abs(y1)<1.5*r);
/// aplicando "divide y reinaras"
r1=cu1&dentroC;
r2=cu1&fueraC&dentromarco
r3=cu2&dentroC&arribaR;
r4=cu2&fueraC&dentromarco&arribaR
r5=cu2&dentroC&abajoR;
r6=cu2&fueraC&dentromarco&abajoR
r7=cu3&dentroC;
r8=cu3&fueraC&dentromarco
r9=cu4&dentroC&abajoR;
r10=cu4&fueraC&dentromarco&abajoR
r11=cu4&dentroC&arribaR;
r12=cu4&fueraC&dentromarco&arribaR
r13=fueramarco
/// si ninguna de las anteriores variables logicas es verdadera,
/// entonces el punto está en la frontera
k=0 /// asumimos que el punto está en la frontera
/// e inspeccionamos todas variables de r1 a r13
si r1 entonces
k=1;
FinSi
si r2 entonces
k=2;
FinSi
si r3 entonces
k=3;
FinSi
si r4 entonces
k=4;
FinSi
si r5 entonces
k=5;
FinSi
si r6 entonces
k=6;
FinSi
si r7 entonces
k=7;
FinSi
si r8 entonces
k=8;
FinSi
si r9 entonces
k=9;
FinSi
si r10 entonces
k=10;
FinSi
si r11 entonces
k=11;
FinSi
si r12 entonces
k=12;
FinSi
si r13 entonces
k=13;
FinSi
Escribir"";Escribir" .. está en la región ",k
FinAlgoritmo
Ejercicios: para las siguientes 3 figuras, escriba un programa PseInt,
uno por cada figura, que ejecute las siguientes acciones: 1) que lea
el valor de la variable r (radio) entre 3.5 y 17.5 (para las figuras 2 y
3); 2) que lea la coordenada de un punto (x1, y1) y 3) que determine
en qué región está la coordenada leída.
NOTA: Obligatorio usar la metodología “divide y reinaras”
1)
2)
3)
/// Fijar el valor de alfa en 0°; lado externo del cuadrado: 3*r
/// Leer radio en el rango de [8 .. 12] con dos decimales;
/// Círculo está dentro del cuadrado cuyo lado es de 3*r
/// Fijar orden del polígono regular inscrito en 3 (N = 3) o sea un triangulo
/// Leer las coordenadas (xp1, yp1) de un punto en el plano cartesiano
/// Rango de lectura para xp1 y yp1 [ -4.25*r .. +4.25*r]
/// Determinar en qué región está la coordenada leída teniendo presente la gráfica
/// Tener presente el concepto "frontera" (región 0), explicado en clase
/// Las operaciones de lectura (“leer”) deben reemplazarse con la función azar
Triángulo inscrito
Región 0 => “Frontera”; Región 13 => Fuera del cuadrado
Algoritmo TallerPoligonosPendientes_A
/// Fijar el valor de alfa en 0°; lado externo del cuadrado:3*r
/// Leer radio en el rango de [8 .. 12] con dos decimales;
/// Círculo está dentro del cuadrado cuyo lado es de 3*r
/// Fijar orden del polígono regular inscrito en 3 (N = 3)
/// Leer las coordenadas (xp1, yp1) de un punto en el plano cartesiano
/// Rango de lectura para xp1 y yp1 [ -4.25*r .. +4.25*r]
/// Determinar en qué región está la coordenada leída teniendo presente la gráfica
/// Tener presente el concepto "frontera" (región 0), explicado en clase
/// Las operaciones de lectura ("leer") deben reemplazarse con la función azar
Definir alfag,betag,i,N Como Entero
Definir r,alfar,betar,alfar2,xp1,yp1,xp2,yp2 Como Real
Definir m1,m2,m3,b1,b2,b3,cte1,cte2,cte3 como real
alfag=0
r=(azar(401)+800)/100
/// aqui en valor de azar estará entre 0 y 400. Al sumar 800, el rango estara entre 800 y
1200
/// Al dividir el resultado por 100 el valor de r queda entre 8.00 y 12.00 que es lo pedido por
el programa
N=3 /// Poligono de tres lados
betag=360/N;betar=(betag*pi/180.0); /// angulo interno del poligono regular
i=1;Escribir"";
mientras alfag<360 hacer
alfar=(alfag*pi/180.0);alfar2=alfar+betar
xp1=r*cos(alfar);yp1=r*sen(alfar);xp2=r*cos(alfar2);yp2=r*sen(alfar2)
Segun i Hacer
1:
si xp2=xp1 entonces
Escribir" .. pendiente 1: tiende a infinito";m1=100000000
b1=0;cte1=xp1
SiNo
m1=(yp2-yp1)/(xp2-xp1);Escribir" .. pendiente 1:",m1
b1=yp1-m1*xp1
FinSi
2:
si xp2=xp1 entonces
Escribir" .. pendiente 2: tiende a infinito";m2=100000000
b2=0;cte2=xp1
SiNo
m2=(yp2-yp1)/(xp2-xp1);Escribir" .. pendiente 2:",m2
b2=yp1-m2*xp1
FinSi
3:
si xp2=xp1 entonces
Escribir" .. pendiente 3: tiende a infinito";m3=100000000
b3=0;cte3=xp1
SiNo
m3=(yp2-yp1)/(xp2-xp1);Escribir" .. pendiente 3:",m3
b3=yp1-m3*xp1
FinSi
FinSegun
alfag=alfag+betag;Escribir"";
i=i+1;
FinMientras
Escribir""
Escribir" .. b1:",b1," .. b2:",b2," .. b3:",b3
Escribir""
/// Analizar con detenimiento la siguiente linea de codigo para los valores de x1 y y1
xp1=((azar(851)-425)/100)*r;yp1=((azar(851)-425)/100)*r;
Escribir" .. r:",r," .. xp1:",xp1," .. yp1:",yp1
si abs(xp1)>3*r | abs(yp1)>3*r entonces
Escribir "Punto por fuera del cuadrado externo"
SiNo
si xp1^2+yp1^2>r^2 Entonces
Escribir "Punto por fuera del círculo"
Finsi
si xp1^2+yp1^2<r^2 Entonces
Escribir "Punto por dentro del círculo"
FinSi
si xp1>0 entonces
si yp1>0 entonces
Escribir "En el primer cuadrante"
si yp1>m1*xp1 + b1 Entonces
Escribir"Por encima de la recta 1"
FinSi
si yp1<m1*xp1 + b1 Entonces
Escribir"Por debajo de la recta 1"
FinSi
SiNo
Escribir "En el cuarto cuadrante"
si yp1>m3*xp1 + b3 Entonces
Escribir"Por encima de la recta 3"
FinSi
si yp1<m3*xp1 + b3 Entonces
Escribir"Por debajo de la recta 3"
FinSi
FinSi
sino /// x1<0
si yp1>0 Entonces
Escribir "En el segundo cuadrante"
si (yp1<m1*xp1 + b1) Entonces
Escribir"Por debajo de la recta 1"
FinSi
si (xp1>cte2) Entonces
Escribir"A la izquierda de la recta 2"
FinSi
si (xp1<cte2) Entonces
Escribir"A la derecha de la recta 2"
FinSi
SiNo
Escribir "En el tercer cuadrante"
si (yp1>m3*xp1 + b3) Entonces
Escribir"Por encima de la recta 3"
FinSi
si (xp1>cte2) Entonces
Escribir"A la izquierda de la recta 2"
FinSi
si (xp1<cte2) Entonces
Escribir"A la derecha de la recta 2"
FinSi
FinSi
FinSi
FinSi
FinAlgoritmo
Definir el lugar geométrico excluyendo el área sombreada de gris oscuro y determine si una
coordenada leída pertenece o no a dicha zona
Lugar geométrico: el área sombreada de gris (se asume conocido r):
Definir el lugar geométrico sombreado de gris oscuro
Para que un punto en cuestión pertenezca al área sombreada de gris, debe al menos cumplirse
una de las cuatro proposiciones siguientes:
1) Que esté en el primer cuadrante dentro del circulo con centro en el origen (0,0) y que esté
por encima de la recta que pasa por los puntos (0, r) y (r, 0)
2) Que esté en el segundo cuadrante dentro del circulo con centro en el origen (0,0) y que
esté por encima de la recta que pasa por los puntos (0, r) y (-r, 0)
3) Que esté en el tercer cuadrante dentro del circulo con centro en el origen (0,0) y que esté
por debajo de la recta que pasa por los puntos (0, -r) y (-r, 0)
4) Que esté en el cuarto cuadrante dentro del circulo con centro en el origen (0,0) y que esté
por debajo de la recta que pasa por los puntos (0, -r) y (r, 0)
Definir el lugar geométrico excluyendo el área sombreada de gris oscuro y determine si una
coordenada leída pertenece o no a dicha zona
Descripción de la figura
Dos círculos concéntricos, ambos con centro en el origen (0, 0); el menor de radio r y el mayor de
radio 2r.
Dentro de la franja limitada por los dos círculos se encuentran cuatro segmentos denominados
así:
a) Segmento 1 superior (cuadrantes 1 y 2) y delimitados por las rectas Y=X y Y=-X
b) Segmento 1 inferior (cuadrantes 3 y 4) y delimitados por las rectas Y=X y Y=-X
c) Segmento 2 derecho (cuadrantes 1 y 4) y delimitados por las rectas Y=X y Y=-X
d) Segmento 2 izquierdo (cuadrantes 2 y 3) y delimitados por las rectas Y=X y Y=-X
Dentro del círculo menor se encuentran cuatro segmentos denominados así:
a) Segmento 5 interior en el cuadrante 1
b) Segmento 3 interior en el cuadrante 2
c) Segmento 6 interior en el cuadrante 3
d) Segmento 4 interior en el cuadrante 4
Fuera del círculo mayor se encuentran cuatro segmentos denominados así:
a) Segmento 4 exterior en el cuadrante 1
b) Segmento 5 exterior en el cuadrante 2
c) Segmento 3 exterior en el cuadrante 3
d) Segmento 6 exterior en el cuadrante 4
Si se reúnen los segmentos descritos podemos definir 6 áreas descritas así:
1) Área 1 = Segmento 1 superior + Segmento 1 inferior
2) Área 2 = Segmento 2 derecho + Segmento 2 izquierdo
3) Área 3 = Segmento 3 interior + Segmento 3 exterior
4) Área 4 = Segmento 4 interior + Segmento 4 exterior
5) Área 5 = Segmento 5 interior + Segmento 5 exterior
6) Área 6 = Segmento 6 interior + Segmento 6 exterior
A su vez, cada de estas áreas, describen 6 lugares geométricos
Descripción de la figura
Círculo con centro en el origen (0, 0) de lado r
Polígono de 4 lados cerrado e inscrito en el círculo (que llamaremos punta de flecha), cuyas
coordenadas son las siguientes: punto 1 sobre el eje X con coordenada (r, 0); punto 2 en el origen
(0, 0); punto 3 (-r/2, r/2* √ 3 ) sobre el círculo a 120o (ciento veinte grados) a partir del punto 1;
punto 4 (-r/2, r/2* √ 3 ) sobre el círculo a 120o (ciento veinte grados) a partir del punto 3.
Los lados menores de la punta de flecha forman un ángulo exterior obtuso de 120 o (ciento veinte
grados) y presentan cada uno una longitud r
Los lados mayores de la punta de flecha forman un ángulo interior agudo de 60 o (sesenta grados)
2
y presentan longitudes iguales de r¿ √ 3 => 2* r 2− r
√ 4
Los lados adyacentes menor y mayor forman un ángulo interior agudo de 30 o (treinta grados)
Area1: la perteneciente a la punta de flecha
Area2: la perteneciente dentro del círculo y excluyendo el área de la punta de flecha
Area3: la perteneciente fuera del círculo
Áreas: 0,1,2,3,A,B,C