Está en la página 1de 5

FILA B

RESOLUCIÓN DE PRUEBA DE DESARROLLO


Estructura selectiva y repetitiva- PSeInt
PREGUNTA 01: Estructura selectiva - Si Entonces (4pts)
• Diseñar un algoritmo que al ingresar un número entero negativo, indique si es o no un
número par. (Validar dato de entrada, debe ser sólo negativo)

Proceso Preg01
Definir N Como Entero;
Escribir "Ingrese número negativo:";
Leer N;

Si N>=0 Entonces
Escribir "Número no válido, debe ser negativo";
Sino
Si (N MOD 2=0) Entonces
Escribir "Si es PAR";
Sino
Escribir "No es PAR”;
FinSi
FinSi
FinProceso
PREGUNTA 02: Estructura selectiva - Según (4pts)
• Diseñar un algoritmo que al ingresar un número entero, muestre el siguiente menú de
opciones y realice una tarea de acuerdo a la opción elegida:
MENÚ DE OPCIONES
----------------
1.- Mensaje si es mayor de 25 o no
2.- Muestra si es divisible por 3
3.- Muestra las dos últimas cifras
Escoja una opción (1-3):_

Proceso Preg02
Definir N,op Como Entero;
Escribir "Ingrese un número:";
Leer N;
Escribir "Menú de opciones: ";
Escribir "================= ";
Escribir "1.- Mensaje si es mayor de 25 o no";
Escribir "2.- Mensaje si es divisible por 3";
Escribir "3.- Muestra las dos últimas cifras";
Escribir "Escoja una opción: ";
Leer op;
Segun op Hacer
1:
Si N>25 Entonces
Escribir "Es mayor de 25";
Sino
Escribir "No es mayor de 25";
FinSi
2:
Si N MOD 3=0 Entonces
Escribir "Es divisible por tres";
Sino
Escribir "No es divisible por tres ";
FinSi
3:
Escribir "Las dos últimas cifras son ",N MOD 100;
De Otro Modo:
Escribir "Opción no válida";
FinSegun
FinProceso
PREGUNTA 03: Estructura repetitiva - Mientras (4pts)
• Diseñe un algoritmo que muestre la serie de números múltiplos de 3 que existen entre dos
números ingresados por teclado, finalmente debe mostrar en pantalla la cantidad de
elementos que tiene la serie.

Proceso Preg03
Definir A, B, C, cant Como Entero;
Escribir "Ingrese dos números (el segundo mayor): ";
Leer A,B;
cant <- 0;
Si A=B Entonces
Escribir "Error no deben ser iguales";
Sino
Si A>B Entonces
Escribir "Error el segundo debe ser mayor";
Sino
Escribir "Serie de ",A," hasta ",B," múltiplos de 3: ";
Escribir "=====================================";
C <- A;
Mientras C<=B Hacer
Si C MOD 3=0 Entonces
Escribir Sin Saltar C, " , ";
cant <- cant+1;
FinSi

C <- C+1;
FinMientras
FinSi
FinSi
Escribir "";
Escribir "Existen ",cant, " elementos en la serie";
FinProceso
PREGUNTA 04: Estructura repetitiva - Mientras (4pts)
• Realice un algoritmo que muestre la tabla de potencias del 0 al 5 de un número entero
ingresado por teclado. Ejemplo si ingreso 8, debe mostrar:
8 a la potencia 0 es 1
8 a la potencia 1 es 8
8 a la potencia 2 es 64
8 a la potencia 3 es 512
8 a la potencia 4 es 4096
8 a la potencia 5 es 32768

Proceso Preg04
Definir C,N como entero;
Escribir "Ingrese un número: ";
Leer N;
Si N=0 Entonces
Escribir "No debe ser cero";
Sino
Escribir "Tabla de potencias de ",N,": ";
Escribir "-------------------------";
C<-0;
Mientras C<=5 Hacer
Escribir N, ", a la potencia de ",C," es ",N^C;
C<-C+1;
FinMientras
FinSi
FinProceso
PREGUNTA 05: Estructura repetitiva - Repetir (4pts)
• Diseñe un algoritmo que pida el ingreso de un número tantas veces hasta que la suma de
todos los números ingresados supere las 1000 unidades. Mostrar un mensaje de finalización.
(Utilice la estructura repetir)

Proceso Preg5
Definir N,sum Como Entero;
sum<-0;
Repetir
Escribir Sin saltar "Ingrese un número: ";
Leer N;
sum<-sum+N;
Escribir "Va sumando ",sum;
Hasta Que sum>1000
Escribir "La suma excedió 1000 unidades";
FinProceso