FINISH

/CLEAR,ALL
/PREP7

/VIEW,1,,-1

!GEOMETRIA (en metros)

!C=5 !ANCHO
H=3 !ALTURA PILAR
L=5 !LUZ

npl1=3
npl2=7
npl=npl1+npl2
npi=6
npi1=1 !menor que npi mayor igual 1
npi2=3 !menor que npi mayor que npi1

H1=0.16 !IPE160
B1=0.082
tw1=0.005
tf1=0.0074

H2=0.12 !HEB120
B2=0.12
tw2=0.0065
tf2=0.011

P=1000 !CARGA (en Newton)

Q=2000 !Carga N/m

!DEFINICION ELEMENTO
ET,1,BEAM188
SECTYPE,1,BEAM,I
SECDATA,B1,B1,H1,tf1,tf1,tw1
SECTYPE,2,BEAM,I
SECDATA,B2,B2,H2,tf2,tf2,tw2
MP,EX,1,2E11
KEYOPT,1,3,3 !interpolacion 0 lineal, 2 cuadrat, 3 cubico

!NODOS

*DO,pla,0,npl
*DO,pil,1,npi
N,pil+npi*pla,L*(pil-1),0,pla*H
*ENDDO
*ENDDO

!/eof

!ELEMENTOS

*DO,pla,1,npl1
SECNUM,2
E,1+(pla-1)*npi,1+pla*npi
*DO,pil,2,npi
SECNUM,2
E,pil+(pla-1)*npi,pil+pla*npi
SECNUM,1
E,pil-1+pla*npi,pil+pla*npi
*ENDDO
*ENDDO

!/eof

*DO,pla,npl1+1,npl
SECNUM,2
E,npi1+(pla-1)*npi,npi1+pla*npi
*DO,pil,npi1+1,npi2
SECNUM,2
E,pil+(pla-1)*npi,pil+pla*npi
SECNUM,1
E,pil-1+pla*npi,pil+pla*npi
*ENDDO
*ENDDO

D,ALL,UY
NSEL,S,LOC,z,0
D,ALL,ALL
NSEL,ALL

ESEL,S,SEC,,1
SFBEAM,ALL,1,PRES,Q
ESEL,ALL

!/eof

FINISH

/SOLU
SOLVE
FINISH

/POST1
PLDISP,1

!/EOF

ETABLE,Ni,SMISC,1 !axil
ETABLE,Nj,SMISC,14

ETABLE,Vyi,SMISC,6 !cortante y
ETABLE,Vyj,SMISC,19

ETABLE,Vzi,SMISC,5 !cortante z
ETABLE,Vzj,SMISC,18

ETABLE,Myi,SMISC,2
ETABLE,Myj,SMISC,15 !flector y

ETABLE,Mzi,SMISC,3
ETABLE,Mzj,SMISC,16 !flector z

ETABLE,Ti,SMISC,4
ETABLE,Tj,SMISC,17 !torsor
PLLS,Myi,Myj