Está en la página 1de 10

UNIVERSIDAD DE EL SALVADOR

FACULTAD DE INGENIERA Y ARQUITECTURA


ESCUELA DE INGENIERA ELCTRICA
ANLISIS ELCTRICO II
CICLO II - 2017

Catedrtico: Ing. Gerardo Marvin Jorge Hernndez.


Instructores: Br. Cristian Antonio Aguilar Quintanilla.
Br. Diego Fernando Guidos Espinoza.

Gua de Simulacin III: Filtros Activos, Parte II.

Ejemplo. El circuito mostrado es un filtro pasabajas de quinto orden con respuesta Chebyshev
implementado con el circuito Antoniou simulador de inductancia. La frecuencia de corte
pasabanda fp es de 10 kHz, la frecuencia en el borde rechazabanda fs es de 15 kHz, la
desviacin de transmisin en la regin pasabanda es de 1 dB, la desviacin de atenuacin en
la regin rechazabanda es de 25 dB, la ganancia en CC es de 1. Para los amplificadores que
estn como seguidores de tensin usar el LM741 y para el resto el LF356. Trazar los
diagramas de Bode de magnitud y fase, realizar un anlisis transitorio para una onda senoidal
de 1kHz con magnitud de 1 V y tambin un anlisis transitorio con una seal de onda
cuadrada con periodo de 1 ms con amplitud mxima positiva de 1 V y amplitud mnima
absoluta de 0 V.

Cdigo en SPICE OPUS:

* Ejemplo.
* Gua de Simulacin III.
* AEL215 Ciclo II-2017.

* Filtro pasabajas Chebyshev con Circuito Antoniou simulador de inductancia


* (filtro_sedra_D1220.cir)
***********
***********
*************************************************************************
*************************************************************************
***********
***********
*********** Disear un filtro pasabajas con funcin de transferencia
*********** Chebyshev con las siguientes especificaciones: fp = 10 kHz,
*********** Amax = 1 dB, fs = 15 kHz, Amin = 25 dB, Ganancia en DC = 1.
***********
*********** Luego implementar el filtro utilizando el circuito
*********** Antoniouv simulador de inductancia.
***********
*********** Se aplicar una onda cuadrada para anlisis el transitorio,
*********** y una onda en AC para el barrido en frecuencia.
*********** Se harn pruebas con el LM741 y el LF356.
***********
***********
*********************** Parmetros del Circuito ******************************
***********
***********
.param Vm = 1V
.param Vs = Vm/sqrt(2)
.param VDD = 15V
.param VSS = -15V
.param f = 1kHz
.param T = 1/f
.param RN1 = 10kOhm
.param CN1 = 1.6nF
.param R6N1 = 55.59kOhm
.param RN2 = 10kOhm
.param CN2 = 2.429nF
.param R6N2 = 13.99kOhm
.param RN3 = 10kOhm
.param CN3 = 5.5nF
***********
***********
*********************** Descripcin del Circuito *****************************
***********
***********
V1 1 0 DC 0V AC {Vs}V 0deg SIN ( 0V {Vm} {f} 0s 0 0deg )
*V1 1 0 DC 0V AC 0V 0deg PULSE ( 0V {Vm} 0s 0s 0s {T/2} {T} )
VDD 15 0 DC {VDD}
VSS 16 0 DC {VSS}
R1 1 2 {RN1}
C1 2 3 {CN1}
R2 3 4 {RN1}
R3 4 5 {RN1}
R4 5 6 {RN1}
C2 6 0 {CN1}
R5 6 0 {R6N1}
X1 2 4 15 16 5 LF356/NS
X2 6 4 15 16 3 LF356/NS
X3 6 7 15 16 7 LM741/NS
R6 7 8 {RN2}
C3 8 9 {CN2}
R7 9 10 {RN2}
R8 10 11 {RN2}
R9 11 12 {RN2}
C4 12 0 {CN2}
R10 12 0 {R6N2}
X4 8 10 15 16 11 LF356/NS
X5 12 10 15 16 9 LF356/NS
X6 12 13 15 16 13 LM741/NS
R11 13 14 {RN3}
C5 14 0 {CN3}
***********
***********
*************************** Subcircuitos ***********************************
*XAMP <Entrada no inversora> <Entrada inversora> <Alimentacin Positiva>
*+ <Alimentacin Negativa> <Nodo de Salida> <Nombre AO>
***********
***********
*//////////////////////////////////////////////////////////
*LM741 OPERATIONAL AMPLIFIER MACRO-MODEL
*//////////////////////////////////////////////////////////
*
* connections: non-inverting input
* | inverting input
* | | positive power supply
* | | | negative power supply
* | | | | output
* | | | | |
* | | | | |
.SUBCKT LM741/NS 1 2 99 50 28
*
*********** Features:
*********** Improved performance over industry standards
*********** Plug-in replacement for LM709,LM201,MC1439,748
*********** Input and output overload protection
***********
*************************** Etapa de Entrada
*********************************
***********
***********
IOS 2 1 20N
*^Corriente de desnivel en la entrada
R1 1 3 250K
R2 3 2 250K
I1 4 50 100U
R3 5 99 517
R4 6 99 517
Q1 5 2 4 QX
Q2 6 7 4 QX
*Fp2=2.55 MHz
C4 5 6 60.3614P
***********
***********
************************** Efecto de Modo Comun
******************************
***********
***********
I2 99 50 1.6MA
*^Quiescent supply current
EOS 7 1 POLY(1) 16 49 1E-3 1
*Voltaje de desnivel en la entrada^
R8 99 49 40K
R9 49 50 40K
***********
***********
********************** Limite del voltaje de salida **************************
***********
***********
V2 99 8 1.63
D1 9 8 DX
D2 10 9 DX
V3 10 50 1.63
***********
***********
**************************** Segunda Etapa
***********************************
***********
***********
EH 99 98 99 49 1
G1 98 9 5 6 2.1E-3
*Fp1=5 Hz
R5 98 9 95.493MEG
C3 98 9 333.33P
***********
***********
******************************* Etapa del polo
*******************************
***********
***********
*Fp=30 MHz
G3 98 15 9 49 1E-6
R12 98 15 1MEG
C5 98 15 5.3052E-15
***********
***********
************************ Etapa del cero en modo comun ************************
***********
***********
*Fpcm=300 Hz
G4 98 16 3 49 3.1623E-8
L2 98 17 530.5M
R13 17 16 1K
***********
***********
**************************** Etapa de salida *********************************
***********
***********
F6 50 99 POLY(1) V6 450U 1
E1 99 23 99 15 1
R16 24 23 25
D5 26 24 DX
V6 26 22 0.65V
R17 23 25 25
D6 25 27 DX
V7 22 27 0.65V
V5 22 21 0.18V
D4 21 15 DX
V4 20 22 0.18V
D3 15 20 DX
L3 22 28 100P
RL3 22 28 100K
***********
***********
************************* Modelos del subcircuito ****************************
***********
***********
.MODEL DX D(IS=1E-15)
.MODEL QX NPN(BF=625)
***********
***********
.ENDS
***********
***********
*//////////////////////////////////////////////////////////////////////
* (C) National Semiconductor, Inc.
* Models developed and under copyright by:
* National Semiconductor, Inc.

*/////////////////////////////////////////////////////////////////////
* Legal Notice: This material is intended for free software support.
* The file may be copied, and distributed; however, reselling the
* material is illegal

*////////////////////////////////////////////////////////////////////
* For ordering or technical information on these models, contact:
* National Semiconductor's Customer Response Center
* 7:00 A.M.--7:00 P.M. U.S. Central Time
* (800) 272-9959
* For Applications support, contact the Internet address:
* amps-apps@galaxy.nsc.com
* ///////////////////////////////////////////////////////////////////
* User Notes:
*
* 1. Input resistance (Rin) for these JFET op amps is 1TOhm. Rin is
* modeled by assuming the option GMIN=1TOhm. If a different (non-
* default) GMIN value is needed, users may recalculate as follows:
* Rin=(R1||GMIN+R2||GMIN), where R1=R2,
* to maintain a consistent Rin model.

*//////////////////////////////////////////////////////////
*LF356 Monolithic JFET-Input OP-AMP MACRO-MODEL
*//////////////////////////////////////////////////////////
*
* connections: non-inverting input
* | inverting input
* | | positive power supply
* | | | negative power supply
* | | | | output
* | | | | |
* | | | | |
.SUBCKT LF356/NS 1 2 99 50 28
*
*Features:
*Low input bias current = 30pA
*Low input offset current = 3pA
*High input impedance = 1Tohm
*Low input offset voltage = 1mV
*
****************INPUT STAGE**************
*
IOS 2 1 3P
*^Input offset current
R1 1 3 1E12
R2 3 2 1E12
I1 99 4 100U
J1 5 2 4 JX
J2 6 7 4 JX
R3 5 50 20K
R4 6 50 20K
*Fp2=20 MHz
C4 5 6 1.9894E-13
*
***********COMMON MODE EFFECT***********
*
I2 99 50 4.65MA
*^Quiescent supply current
EOS 7 1 POLY(1) 16 49 3E-3 1
*Input offset voltage.^
R8 99 49 50K
R9 49 50 50K
*
*********OUTPUT VOLTAGE LIMITING********
V2 99 8 2.63
D1 9 8 DX
D2 10 9 DX
V3 10 50 2.63
*
**************SECOND STAGE**************
*
EH 99 98 99 49 1
F1 9 98 POLY(1) VA3 0 0 0 1.5944E7
G1 98 9 5 6 2E-3
R5 98 9 100MEG
VA3 9 11 0
*Fp1=31.96 HZ
C3 98 11 49.9798P
*
*********COMMON-MODE ZERO STAGE*********
*
G4 98 16 3 49 1E-8
L2 98 17 530.52M
R13 17 16 1K
*
**************OUTPUT STAGE**************
*
F6 99 50 VA7 1
F5 99 23 VA8 1
D5 21 23 DX
VA7 99 21 0
D6 23 99 DX
E1 99 26 99 9 1
VA8 26 27 0
R16 27 28 20
V5 28 25 -.25V
D4 25 9 DX
V4 24 28 -.25V
D3 9 24 DX
*
***************MODELS USED**************
*
.MODEL DX D(IS=1E-15)
.MODEL JX PJF(BETA=1.25E-5 VTO=-2.00 IS=30E-12)
*
.ENDS
*$
***********
***********
.control
***********
***********
************************ Respuesta en Frecuencia ****************************
***********
***********
set units=degress
ac dec 1000 10Hz 100kHz
plot dB(V(14)/V(1)) vs (frequency/1k) xlabel 'Frecuencia [kHz]'
+ylabel 'Ganancia [dB]' title 'Diagrama de Bode de la magnitud de Vout/Vin'
plot ph(V(14)/V(1)) vs (frequency/1k) xlabel 'Frecuencia [kHz]'
+ylabel 'Angulo [Grados]' title 'Diagrama de Bode de la fase de Vout/Vin'
***********
***********
************************ Anlisis Transitorio ********************************
***********
***********
*tran 0.1us 4ms 0ms 1us
*plot V(14) V(1) vs (time*1k) xlabel 'Tiempo [ms]' ylabel 'Tension [V]'
*+title 'Tension de salida (rojo), tension de entrada (verde)'
.endc
.end