/PREP7

B= 800 !cm
H= 350 !cm
ZH = 50 !cm
B1=100 !cm
LZ = 3*B +B1
L1= 1000 !cm
H1= 1500 !cm
g=981 !cm/s2
!crear kpoins

K,1000,0,0
K,2000,L1,0

*DO,i,1,4,1

k,i,L1+(i-1)*B,H1+ZH+H,0
k,i+4,L1+(i-1)*B,H1+ZH+2*H,0
k,i+8,L1+(i-1)*B,H1+ZH+3*H,0
k,i+12,L1+(i-1)*B,H1+ZH+4*H,0
*enddo

BLC4,L1-B1,H1,B1,ZH
BLC4,L1+3*B,H1,B1,ZH
*DO,i,0,2,1

BLC4,L1+i*B,H1,B,ZH
*ENDDO
aglue,all

!lineas

*do,i,1,3,1
L,i,i+1
L,i+4,i+5
L,i+8,i+9
L,i+12,i+13
*enddo

L,19,1
L,27,2
L,31,3
L,24,4
*DO,i,1,9,4
L,i,i+4
L,i+1,i+5
L,i+2,i+6
L,i+3,i+7
*enddo
!=============================================================
ET,1,188

SECTYPE, 1, BEAM, I, W18X97, 0

SECOFFSET, CENT
SECDATA,28.194,28.194,47.244,2.21,2.21,1.359,0,0,0,0,0,0

SECTYPE, 2, BEAM, I, W18X86, 0

SECOFFSET, CENT
SECDATA,28.194,28.194,46.736,1.956,1.956,1.219,0,0,0,0,0,0

SECTYPE, 3, BEAM, I, W21X122, 0

SECOFFSET, CENT
SECDATA,31.496,31.496,55.118,2.438,2.438,1.524,0,0,0,0,0,0

SECTYPE, 4, BEAM, I, W21X111, 0

SECOFFSET, CENT
SECDATA,31.242,31.242,54.61,2.223,2.223,1.397,0,0,0,0,0,0

SECTYPE, 5, BEAM, I, W16X67, 0

SECOFFSET, CENT
SECDATA,25.908,25.908,41.402,1.689,1.689,1.003,0,0,0,0,0,0

SECTYPE, 6, BEAM, I, W16X57, 0

SECOFFSET, CENT
SECDATA,18.085,18.085,41.656,1.816,1.816,1.092,0,0,0,0,0,0

SECTYPE, 7, BEAM, I, W16X45, 0

SECOFFSET, CENT
SECDATA,17.887,17.887,40.894,1.435,1.435,0.876,0,0,0,0,0,0

SECTYPE, 8, BEAM, I, W16X40, 0

SECOFFSET, CENT
SECDATA,17.7673,17.7673,40.6654,1.2827,1.2827,0.7747,0,0,0,0,0,0
!=======================================================================

MP,EX,1,2038901.9 !kg/cm2
MP,NUXY,1,0.3
MP,DENS,1,8.0E-06 !kg/cm3 densidad
MP,DAMP,1,0.03 !AMORTIGUAMIENTO del 3%
MP,GXY,1,2038901.9/(2*(1+0.3))

!MP,ALPD,1,0.1611

!MP,BETD,1,5.439e-03

TB,BISO,1,1,2
TBDATA,,3796.576,4485.5842,,,, !ESFUERZO DE FLUENCIA(Fy) y ESFUERZO LTIMO(Fu)
kg/cm2

!FALTA EL MATERIAL DE LA ZAPATA PERO COMO SER EMPOTRADO

!EN LOS EXTREMOS DE LA COLUMNA, DESPUS LO AGREGARMOS

!PARA LAS COLUMNAS EXTERIORES DEL LOS NIVELES N1 Y N2

malla1=10
LSEL,S,,,29,33,4
LSEL,A,,,32,36,4
LATT,1,,1, ,1000, ,1 !SECCION 1
!MALLADO
lesize,all,,,malla1
!crear elemento finito
lmesh,all
lsel,all

!PARA LAS COLUMNAS EXTERIORES DEL LOS NIVELES N3 Y N4

LSEL,S,,,37,41,4
LSEL,A,,,40,44,4
LATT,1,,1, ,1000, ,2 !SECCION 2
!MALLADO
lesize,all,,,malla1
!crear elemento finito
lmesh,all
lsel,all

!PARA LAS COLUMNAS INTERIORES DEL LOS NIVELES N1 Y N2

LSEL,S,,,30,34,4
LSEL,A,,,31,35,4
LATT,1,,1, ,1000, ,3 !SECCION 3
!MALLADO
lesize,all,,,malla1
!crear elemento finito
lmesh,all
lsel,all

!PARA LAS COLUMNAS INTERIORES DEL LOS NIVELES N3 Y N4

LSEL,S,,,38,42,4
LSEL,A,,,39,43,4
LATT,1,,1, ,1000, ,4 !SECCION 4
!MALLADO
lesize,all,,,malla1
!crear elemento finito
lmesh,all
lsel,all

!PARA LAS VIGAS NIVEL N1

lsel,s,loc,y,H1+H+ZH

LATT,1,,1, ,2000, ,5 !SECCION 5

!MALLADO
lesize,all,,,malla1
!crear elemento finito
lmesh,all
lsel,all

!PARA LAS VIGAS NIVEL N2

lsel,s,loc,y,H1+2*H+ZH
LATT,1,,1, ,2000, ,6 !SECCION 6
!MALLADO
lesize,all,,,malla1
!crear elemento finito
lmesh,all
lsel,all
!PARA LAS VIGAS NIVEL N3

lsel,s,loc,y,H1+3*H+ZH
LATT,1,,1, ,2000, ,7 !SECCION 7
!MALLADO
lesize,all,,,malla1
!crear elemento finito
lmesh,all
lsel,all

!PARA LAS VIGAS NIVEL N4

lsel,s,loc,y,H1+4*H+ZH
LATT,1,,1, ,2000, ,8 !SECCION 8
!MALLADO
lesize,all,,,malla1
!crear elemento finito
lmesh,all
lsel,all

finish

/solu

nsel,s,loc,y,H1+ZH
D,all, ,0.0, , , ,ALL, , , , ,
nsel,all

nsel,s,loc,X,L1
nsel,A,loc,X,L1+B
nsel,A,loc,X,L1+2*B
nsel,A,loc,X,L1+3*B
nsel,A,loc,y,H1+ZH+H
nsel,A,loc,y,H1+ZH+2*H
nsel,A,loc,y,H1+ZH+3*H
nsel,A,loc,y,H1+ZH+4*H
D,all, ,0.0, , , ,UZ, , , , ,
nsel,all

ALLSEL,ALL
*SET,NT,1560
*SET,DT,0.02
*DIM,AC,,NT
*VREAD,AC(1),RECORD3-2,TXT
(F8.3)

ANTYPE,TRANS
NLGEOM,1 !grandes desplazamientos.
NSUBST,1,10,1

CNVTOL,F, 9000,0.5 ! FORCE CONVERGENCE

CNVTOL,U,3.8,0.5 ! DISPLACEMENT CONVERGENCE
nropt,full ! Newton Raphson = full

lumpm,0 ! Lumped mass approx off

neqit,100 ! Max no. of iterations = 100
autots,OFF! Auto time search on
lnsrch,ON ! Line search on
outres,all,all ! Output data for all substeps
kbc,1
SAVE

acel,0,-g,0

*DO,I,1,1560
ACEL,AC(I)*g*5,0,0
TIME,I*0.02
OUTRES,ALL,ALL
SOLVE
*ENDDO

finish
/POST1
*do,i,1,1560
SET,i
nsel,s,loc,y,H1+ZH
*GET,NUMNOD,NODE,0,COUNT
*GET,CURNOD,NODE,0,NUM,MIN
Vbase=0
*DO,I2,1,NUMNOD
*GET,RFX,NODE,CURNOD,RF,FX
Vbase=Vbase+RFX
CURNOD=NDNEXT(CURNOD)
*ENDDO
disj=Ux(143)
ALLSEL,ALL
/OUTPUT,Suelo_Estr-700,OUT,,APPEND
*VWRITE,i,DISj,i,Vbase
(F16.8,5X,F16.8,5X,F16.8,5X,F16.8)
/OUTPUT
*enddo